求救！！我将word文档保存在SQL Server数据库中，不知如何取出来啊！！！（高分）

Question

我保存的程序如下（将文档转换成二进制保存）   
    Dim MsStream As New ADODB.Stream
    Dim Rst As ADODB.Recordset
        
        Call SetRst(Rst, "select * from document ")  ’打开一个SQL数据库表名document 
         
        MsStream.Type = adTypeBinary
        MsStream.open
        MsStream.LoadFromFile App.Path + "\模板2.doc" '"Word文件的存放路径"
        Rst.AddNew
        Rst.Fields("title") = "模板2"
        Rst.Fields("data") = data()
        Rst.Fields("contant") = MsStream.Read 'contant数据类型为image
        
        MsStream.Close
        Rst.Update        'rst为你想要保存到数据库中某个表的记录集
        Rst.Close
我想读取contant的内容，还是用word 文档打开。
请高手赐教！！

Answer 1

'读出数据
Public Function LoadFile(ByVal col As ADODB.Field, ByVal fileName As String) As Boolean '获得binary数据
    On Error GoTo myerr:
     Dim arrBytes() As Byte
     Dim FreeFileNumber As Integer
     lngsize = col.ActualSize
     arrBytes = col.GetChunk(lngsize)
     FreeFileNumber = FreeFile
     Open fileName For Binary Access Write As #FreeFileNumber
     Put #FreeFileNumber, , arrBytes
     Close #FreeFileNumber
     LoadFile = True
myerr:
     If Err.Number <> 0 Then
     LoadFile = False
     Err.Clear
     End If
End Function'用Word打开文件
Sub OpenDoc(filename as string)
    Dim WordTemps As New Word.Application
    WordTemps.Documents.Add fileName , False    WordTemps.Visible = True
End Sub

Answer 2

'*************************************************************************
'**
'** 使用 ADODB.Stream 保存/读取文件到数据库
'** 引用 Microsoft ActiveX Data Objects 2.5 Library 及以上版本
'**
'** ----- 数据库连接字符串模板 ---------------------------------------
'** ACCESS数据库
'** iConcStr = "Provider=Microsoft.Jet.OLEDB.4.0;Persist Security Info=False" & _
'**     ";Data Source=数据库名"
'**
'** SQL数据库
'** iConcStr = "Provider=SQLOLEDB.1;Persist Security Info=True;" & _
'**     "User ID=用户名;Password=密码;Initial Catalog=数据库名;Data Source=SQL服务器名"
'**
'*************************************************************************
'
'保存文件到数据库中
Sub s_SaveFile()
    Dim iStm As ADODB.Stream
    Dim iRe As ADODB.Recordset
    Dim iConcStr As String
    
    '数据库连接字符串
    iConcStr = "Provider=Microsoft.Jet.OLEDB.4.0;Persist Security Info=False" & _
        ";Data Source=F:\My Documents\客户资料1.mdb"
    
    '读取文件到内容
    Set iStm = New ADODB.Stream
    With iStm
        .Type = adTypeBinary    '二进制模式
        .Open
        .LoadFromFile "c:\test.doc"
    End With
    
    '打开保存文件的表
    Set iRe = New ADODB.Recordset
    With iRe
        .Open "表", iConc, adOpenKeyset, adLockOptimistic
        .AddNew         '新增一条记录
        .Fields("保存文件内容的字段") = iStm.Read
        .Update
    End With
    
    '完成后关闭对象
    iRe.Close
    iStm.Close
End Sub'从数据库中读取数据,保存成文件
Sub s_ReadFile()
    Dim iStm As ADODB.Stream
    Dim iRe As ADODB.Recordset
    Dim iConc As String
    
    '数据库连接字符串
    iConc = "Provider=Microsoft.Jet.OLEDB.4.0;Persist Security Info=False" & _
        ";Data Source=\\xz\c$\Inetpub\zj\zj\zj.mdb"
    
    '打开表
    Set iRe = New ADODB.Recordset
    iRe.Open "tb_img", iConc, adOpenKeyset, adLockReadOnly
    iRe.Filter = "id=64"
    
    '保存到文件
    Set iStm = New ADODB.Stream
    With iStm
        .Mode = adModeReadWrite
        .Type = adTypeBinary
        .Open
        .Write iRe("img")
        .SaveToFile "c:\test.doc"
    End With
    
    '关闭对象
    iRe.Close
    iStm.Close
End Sub

Answer 3

更多的参考我的贴子：数据库中存/取文件
http：//expert.csdn.net/Expert/topic/2403/2403509.xml?temp=8.602542E-02