存储过程导出问题，请高手

Question

用 邹建老大2003.10的sql导出dbf的存储过程
*调用示例    
   
 --导出dBase    
   
 --p_exporttb @tbname='地区资料',@path='c:\',@over=0    
   
*/    
   
CREATE proc p_exporttb    
   
@tbname sysname,    --要导出的表名    
   
@path nvarchar(1000),   --文件存放目录    
...........................................在sql2000下执行p_exporttb @tbname='地区资料',@path='c:\',@over=0 可以顺利导出，但在sql2005下却显示：
消息 102，级别 15，状态 1，第 3 行，'p_exporttb' 附近有语法错误。
该怎样办？

Answer 1

用下面的过程之后，在sql2000下执行p_exporttb @tbname='bbb',@path='c:\',@over=0通过：
/*--数据导出dBase   
    
  导出查询语句中的数据到dBase,如果文件不存在,将自动创建文件   
  基于通用性考虑,仅支持导出标准数据类型   
  --邹建   2003.10--*/   
    /*调用示例    
   
 --导出dBase    
   
 --p_exporttb @tbname='bmk',@path='c:\',@over=0    
   
*/    
   
CREATE proc p_exporttb    
   
@tbname sysname,    --要导出的表名    
   
@path nvarchar(1000),   --文件存放目录    
   
@fname nvarchar(250)='',  --文件名,默认为表名    
   
@over bit=0      --是否覆盖已经存在的文件,如果不覆盖,则直接追加    
   
as   
   
declare @err int,@src nvarchar(255),@desc nvarchar(255),@out int   
   
declare @obj int,@constr nvarchar(1000),@sql varchar(8000),@fdlist varchar(8000)    
   
   
--参数检测    
   
if isnull(@fname,'')='' set @fname=@tbname+'.dbf'   
   
   
--检查文件是否已经存在    
   
if right(@path,1)<>'\' set @path=@path+'\'    
   
create table #tb(a bit,b bit,c bit)    
   
set @sql=@path+@fname    
   
insert into #tb exec master..xp_fileexist @sql    
   
if exists(select 1 from #tb where a=1)    
   
 if @over=1    
   
 begin   
   
  set @sql='del '+@sql    
   
  exec master..xp_cmdshell @sql,no_output    
   
 end   
   
 else   
   
  set @over=0    
   
else   
   
 set @over=1    
   
     
--数据库创建语句    
   
set @sql=@path+@fname    
   
set @constr='Provider=Microsoft.Jet.OLEDB.4.0;Extended Properties="dBASE 5.0;'   
   
 +';HDR=NO;DATABASE='+@path+'"'   
   
     
--连接数据库    
   
exec @err=sp_oacreate 'adodb.connection',@obj out   
   
if @err<>0 goto lberr    
   
     
exec @err=sp_oamethod @obj,'open',null,@constr    
   
if @err<>0 goto lberr    
     
   
--创建表的SQL    
   
select @sql='',@fdlist=''   
   
select @fdlist=@fdlist+','+a.name   
   
 ,@sql=@sql+',['+a.name+'] '   
   
  +case when b.name in('char','nchar','varchar','nvarchar') then   
   
     'text('+cast(case when a.length>250 then 250 else a.length end as varchar)+')'   
   
   when b.name in('tynyint','int','bigint','tinyint') then 'int'   
   
   when b.name in('smalldatetime','datetime') then 'datetime'   
   
   when b.name in('money','smallmoney') then 'money'   
   
   else b.name end   
   
FROM syscolumns a left join systypes b on a.xtype=b.xusertype    
   
where b.name not in('image','text','uniqueidentifier','sql_variant','ntext','varbinary','binary','timestamp')    
   
 and object_id(@tbname)=id    
   
select @sql='create table ['+@fname    
   
 +']('+substring(@sql,2,8000)+')'   
   
 ,@fdlist=substring(@fdlist,2,8000)    
     
   
if @over=1    
   
begin   
   
 exec @err=sp_oamethod @obj,'execute',@out out,@sql    
   
 if @err<>0 goto lberr    
   
end   
     
   
exec @err=sp_oadestroy @obj    
     
   
set @sql='openrowset(''MICROSOFT.JET.OLEDB.4.0'',''dBase 5.0;DATABASE='   
   
 +@path+''',''select * from ['+@fname+']'')'   
     
   
--导入数据    
   
exec('insert into '+@sql+'('+@fdlist+') select '+@fdlist+' from '+@tbname)    
   
     
return   
     
   
lberr:    
   
 exec sp_oageterrorinfo 0,@src out,@desc out   
   
lbexit:    
   
 select cast(@err as varbinary(4)) as 错误号    
   
  ,@src as 错误源,@desc as 错误描述    
   
 select @sql,@constr,@fdlist    
GO   

Answer 2

--用BULK INSERT语句呢?
--/* FoxPro 数据库 
select * from openrowset('MSDASQL', 
'Driver=Microsoft Visual FoxPro Driver;SourceType=DBF;SourceDB=c:\', 
'select * from [aa.DBF]') 
--*/ /**************导入DBF文件****************/ 
select * from openrowset('MSDASQL', 
'Driver=Microsoft Visual FoxPro Driver; 
SourceDB=e:\VFP98\data; 
SourceType=DBF', 
'select * from customer where country != "USA" order by country') 
go 
/***************** 导出到DBF ************** 
如果要导出数据到已经生成结构(即现存的)FOXPRO表中,可以直接用下面的SQL语句 */insert into openrowset('MSDASQL', 
'Driver=Microsoft Visual FoxPro Driver;SourceType=DBF;SourceDB=c:\', 
'select * from [aa.DBF]') 
select * from 表 /*说明: 
SourceDB=c:\ 指定foxpro表所在的文件夹 
aa.DBF 指定foxpro表的文件名. */

Answer 3

/*********************************/
/*把sql server中表导入到dbf文件中*/
/*********************************/
/*--调用示例
exec p_exporttb @tbname='dm_mj',@cols='mj,mjm',@path='g:\',@fname='x1056604.dbf',@over=1
exec p_exporttb @tbname='dm_mj',@path='g:\',@fname='x1056604.dbf',@over=1
--*/
if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_exporttb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_exporttb]
GO
create proc p_exporttb
@tbname sysname,    --要导出的表名
@cols  nvarchar(1000)=null, --要导出的表的列名字符串，格式：'col1,col2,col3',如果没有给出值，则认为是所有字段
@path nvarchar(1000),   --文件存放目录
@fname nvarchar(250)='',  --文件名,默认为表名
@over bit=0      --是否覆盖已经存在的文件,如果不覆盖,则直接追加
as
SET NOCOUNT ON 
declare @err int,@src nvarchar(255),@desc nvarchar(255),@out int
declare @obj int,@constr nvarchar(1000),@sql varchar(8000),@fdlist varchar(8000)
 
--参数检测
if @fname is null or ltrim(rtrim(@fname))=''  set @fname=@tbname+'.dbf'
 
--检查文件是否已经存在
if right(@path,1)<>'\' set @path=@path+'\'
create table #tb(a bit,b bit,c bit)
set @sql=@path+@fname
insert into #tb exec master..xp_fileexist @sql
if exists(select 1 from #tb where a=1)
 if @over=1
 begin
  set @sql='del '+@sql
  exec master..xp_cmdshell @sql,no_output
 end
 else
  set @over=0
else
 set @over=1
--删除临时表
drop table #tb
--数据库创建语句
set @sql=@path+@fname
set @constr='Provider=Microsoft.Jet.OLEDB.4.0;Extended Properties="dBASE 5.0;'
 +';HDR=NO;DATABASE='+@path+'"'
 
--连接数据库
exec @err=sp_oacreate 'adodb.connection',@obj out
if @err<>0 goto lberr
 
exec @err=sp_oamethod @obj,'open',null,@constr
if @err<>0 goto lberr
 
--创建表的SQL
select @sql='',@fdlist=''
--如下判断@cols是否有值，如果没有值则认为是全部的列
if @cols is null or rtrim(ltrim(@cols))=''
 select @fdlist=@fdlist+','+a.name
  ,@sql=@sql+',['+a.name+'] '
   +case when b.name in('char','nchar','varchar','nvarchar') then
     'text('+cast(case when a.length>250 then 250 else a.length end as varchar)+')'
   when b.name in('tynyint','int','bigint','tinyint') then 'int'
   when b.name in('smalldatetime','datetime') then 'datetime'
   when b.name in('money','smallmoney') then 'money'
   else b.name end
 FROM syscolumns a left join systypes b on a.xtype=b.xusertype
 where b.name not in('image','text','uniqueidentifier','sql_variant','ntext','varbinary','binary','timestamp')
  and object_id(@tbname)=id 
else 
 select @fdlist=@fdlist+','+a.name
  ,@sql=@sql+',['+a.name+'] '
   +case when b.name in('char','nchar','varchar','nvarchar') then
     'text('+cast(case when a.length>250 then 250 else a.length end as varchar)+')'
   when b.name in('tynyint','int','bigint','tinyint') then 'int'
   when b.name in('smalldatetime','datetime') then 'datetime'
   when b.name in('money','smallmoney') then 'money'
   else b.name end
 FROM syscolumns a left join systypes b on a.xtype=b.xusertype
 where b.name not in('image','text','uniqueidentifier','sql_variant','ntext','varbinary','binary','timestamp')
  and object_id(@tbname)=id  and CHARINDEX(a.name,@cols)<>0
select @sql='create table ['+@fname
 +']('+substring(@sql,2,8000)+')'
 ,@fdlist=substring(@fdlist,2,8000)
 
if @over=1
begin
 exec @err=sp_oamethod @obj,'execute',@out out,@sql
 if @err<>0 goto lberr
end
 
exec @err=sp_oadestroy @obj
 
set @sql='openrowset(''MICROSOFT.JET.OLEDB.4.0'',''dBase 5.0;DATABASE='
 +@path+''',''select * from ['+@fname+']'')'
 
--导入数据
exec('insert into '+@sql+'('+@fdlist+') select '+@fdlist+' from '+@tbname)
 
return
 
lberr:
 exec sp_oageterrorinfo 0,@src out,@desc out
lbexit:
 select cast(@err as varbinary(4)) as 错误号
  ,@src as 错误源,@desc as 错误描述
 select @sql,@constr,@fdlistSET NOCOUNT Off 
go/********************/
/*删除文件的存储过程*/
/********************/
/*--调用示例
exec p_delfile @path='g:\',@fname='x1056604.dbf'
--*/
if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_delfile]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_delfile]
GO
create proc p_delfile
@path nvarchar(1000),   --文件存放目录
@fname nvarchar(250)=''  --文件名,默认为表名
as
declare @sql varchar(1000)
--检查文件是否已经存在
if right(@path,1)<>'\' set @path=@path+'\'
create table #tb(a bit,b bit,c bit)
set @sql=@path+@fname
insert into #tb exec master..xp_fileexist @sql
if exists(select 1 from #tb where a=1)
 begin
  set @sql='del '+@sql
  exec master..xp_cmdshell @sql,no_output
 end
drop table #tb
go