求一SQL问题

Question

加班申请表:(因为验厂需要，加班可能拆成了多部分)工号               部门       日期                     加班名称
1907 制二课 2011-01-20 00:00:00.000 平加3
1907       制二课 2011-01-20 00:00:00.000 DIP加班2
1011              制一课   2011-01-20 00:00:00.000     平加3 
1011              制一课   2011-01-20 00:00:00.000     平加4
1031              制一课   2011-01-20 00:00:00.000     平加3
.
.
.我要的结果：考勤表(为了方便考勤，将加班合多为一，其中，加班小时数有sum函数。但是加班名称也要合在一起，如下图)工号   部门      日期                          加班名称
1907   制二课    2011-01-20 00:00:00.000       平加3，DIP加班2
1011   制一课    2011-01-20 00:00:00.000       平加3，平加4
1031   制一课    2011-01-20 00:00:00.000       平加3
.
.
.

Answer 1

/*
标题：按某字段合并字符串之一(简单合并)
作者：爱新觉罗.毓华(十八年风雨,守得冰山雪莲花开)
时间：2008-11-06
地点：广东深圳描述：将如下形式的数据按id字段合并value字段。
id    value
----- ------
1     aa
1     bb
2     aaa
2     bbb
2     ccc
需要得到结果：
id     value
------ -----------
1      aa,bb
2      aaa,bbb,ccc
即：group by id, 求 value 的和（字符串相加）
*/
--1、sql2000中只能用自定义的函数解决
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
gocreate function dbo.f_str(@id varchar(10)) returns varchar(1000)
as
begin
  declare @str varchar(1000)
  select @str = isnull(@str + ',' , '') + cast(value as varchar) from tb where id = @id
  return @str
end
go--调用函数
select id , value = dbo.f_str(id) from tb group by iddrop function dbo.f_str
drop table tb
--2、sql2005中的方法
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
goselect id, [value] = stuff((select ',' + [value] from tb t where id = tb.id for xml path('')) , 1 , 1 , '')
from tb
group by iddrop table tb
--3、使用游标合并数据
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go
declare @t table(id int,value varchar(100))--定义结果集表变量
--定义游标并进行合并处理
declare my_cursor cursor local for
select id , value from tb
declare @id_old int , @id int , @value varchar(10) , @s varchar(100)
open my_cursor
fetch my_cursor into @id , @value
select @id_old = @id , @s=''
while @@FETCH_STATUS = 0
begin
    if @id = @id_old
       select @s = @s + ',' + cast(@value as varchar)
    else
      begin
        insert @t values(@id_old , stuff(@s,1,1,''))
        select @s = ',' + cast(@value as varchar) , @id_old = @id
      end
    fetch my_cursor into @id , @value
END
insert @t values(@id_old , stuff(@s,1,1,''))
close my_cursor
deallocate my_cursorselect * from @t
drop table tb

Answer 2

select 工号,部门,日期,
     加班名称=stuff((select ','+加班名称 from tb 
    where 部门=a.部门 and 工号=a.工号 and 日期=a.日期 for xml path('')),1,1,'')
from tb a group by 工号,部门,日期

Answer 3

select 工号,部门,日期,stuff((select ',' + 加班名称 from tb where 工号 = t.工号 and 部门 = t.部门 
                   and convert(varchar(8),日期,112) = convert(varchar(8),t.日期,112) for xml path('')),1,1,'')加班名称
from tb t
group by 工号,部门,convert(varchar(8),日期,112)