api 调整打印机的横纵？

Question

以前用过，现在记不起来了！

Answer 1

Private Type DevMode
    dmDeviceName As String * 32
    dmSpecVersion As Integer
    dmDriverVersion As Integer
    dmSize As Integer
    dmDriverExtra As Integer
    dmFields As Long
    dmOrientation As Integer
    dmPaperSize As Integer
    dmPaperLength As Integer
    dmPaperWidth As Integer
    dmScale As Integer
    dmCopies As Integer
    dmDefaultSource As Integer
    dmPrintQuality As Integer
    dmColor As Integer
    dmDuplex As Integer
    dmYResolution As Integer
    dmTTOption As Integer
    dmCollate As Integer
    dmFormName As String * 32
    dmUnusedPadding As Integer
    dmBitsPerPel As Integer
    dmPelsWidth As Long
    dmPelsHeight As Long
    dmDisplayFlags As Long
    dmDisplayFrequency As Long
End Type
Private Type Printer_Defaults
    pDatatype As String
    pDevMode As Long
    DesiredAccess As Long
End Type
Private Type Printer_Info_2
    pServerName As Long
    pPrinterName As Long
    pShareName As Long
    pPortName As Long
    pDeviceName As Long
    pComment As Long
    pLocation As Long
    pDevMode As Long
    pSepFile As Long
    pPrinterProcessor As Long
    pDatatype As Long
    pParameters As Long
    pSecurityDescripter As Long
    Attributes As Long
    Priority As Long
    DefaultPriority As Long
    StartTime As Long
    UntilTime As Long
    Status As Long
    cJobs As Long
    AveragePPM As Long
End Type
Public Const DM_IN_BUFFER As Long = 8
Public Const DM_OUT_BUFFER As Long = 2
Public Const DM_ORIENTATION As Long = &H1
Public Const DM_PAPERSIZE = &H2&Public Const PRINTER_ACCESS_ADMINISTER As Long = &H4
Public Const PRINTER_ACCESS_USE As Long = &H8
Public Const STANDARD_RIGHTS_REQUIRED As Long = &HF0000
Public Const PRINTER_ALL_ACCESS = (STANDARD_RIGHTS_REQUIRED Or PRINTER_ACCESS_ADMINISTER Or PRINTER_ACCESS_USE)Public Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (hpvDest As Any, hpvSource As Any, ByVal cbCopy As Long)
Public Declare Function OpenPrinter Lib "winspool.drv" Alias "OpenPrinterA" (ByVal pPrinterName As String, phPrinter As Long, pDefault As Any) As Long
Public Declare Function ClosePrinter Lib "winspool.drv" (ByVal hPrinter As Long) As Long
Public Declare Function DocumentProperties Lib "winspool.drv" Alias "DocumentPropertiesA" (ByVal hWnd As Long, ByVal hPrinter As Long, ByVal pDeviceName As String, pDevModeOutput_ As Any, pDevModeInput As Any, ByVal fMode As Long) As Long
Private Declare Function GetPrinter Lib "winspool.drv" Alias "GetPrinterA" (ByVal hPrinter As Long, ByVal Level As Long, pPrinter As Any, ByVal cbBuf As Long, pcbNeeded As Long) As Long
Private Declare Function SetPrinter Lib "winspool.drv" Alias "SetPrinterA" (ByVal hPrinter As Long, ByVal Level As Long, pPrinter As Any, ByVal Command As Long) As LongFunction SetDefaultPrinterOrientation(ByVal eOrientation As Integer) As Boolean '1:“纵向”打印,2:“横向”打印
Dim bDevMode() As Byte
Dim bPrinterInfo2() As Byte
Dim hPrinter As Long
Dim lResult As Long
Dim nSize As Long
Dim sPrnName As String
Dim dm As DevMode
Dim pd As Printer_Defaults
Dim pi2 As Printer_Info_2
' 获取默认打印机的设备名称
sPrnName = Printer.DeviceName
'由于要调用SetPrinter，所以
'如果是在NT下就要求PRINTER_ALL_ACCESS
pd.DesiredAccess = PRINTER_ALL_ACCESS
'获取打印机句柄
If OpenPrinter(sPrnName, hPrinter, pd) Then
' 获取PRINTER_INFO_2结构要求的字节数
    Call GetPrinter(hPrinter, 2&, 0&, 0&, nSize)
    ReDim bPrinterInfo2(1 To nSize) As Byte
    lResult = GetPrinter(hPrinter, 2, bPrinterInfo2(1), nSize, nSize)
    Call CopyMemory(pi2, bPrinterInfo2(1), Len(pi2))
    nSize = DocumentProperties(0&, hPrinter, sPrnName, 0&, 0&, 0)
    ReDim bDevMode(1 To nSize)
    If pi2.pDevMode Then
        Call CopyMemory(bDevMode(1), ByVal pi2.pDevMode, Len(dm))
    Else
        Call DocumentProperties(0&, hPrinter, sPrnName, bDevMode(1), 0&, DM_OUT_BUFFER)
    End If
    Call CopyMemory(dm, bDevMode(1), Len(dm))
    With dm
    ' 设置新的走向
        .dmOrientation = eOrientation
        .dmFields = DM_ORIENTATION
'        .dmPaperSize = DMPAPER_A4
'        '将纸张大小设为A4，请自行更改所需大小
'        .dmFields = 1 ' DM_PAPERSIZE
        '必须，否则无法设置纸张大小
     End With
     Call CopyMemory(bDevMode(1), dm, Len(dm))
     Call DocumentProperties(0&, hPrinter, sPrnName, bDevMode(1), bDevMode(1), DM_IN_BUFFER Or DM_OUT_BUFFER)
    pi2.pDevMode = VarPtr(bDevMode(1))
    lResult = SetPrinter(hPrinter, 2, pi2, 0&)
    Call ClosePrinter(hPrinter)
    SetDefaultPrinterOrientation = True
Else
    SetDefaultPrinterOrientation = False
End If
End Function