在程序报这个错:
未能处理对象 'select * from [W09CHN]'。OLE DB 提供程序 'MICROSOFT.JET.OLEDB.4.0' 指出该对象中没有任何列。我调用一个存储过程,是生成dbf的:--创建新的DBF数据文件
set @constr='Provider=Microsoft.Jet.OLEDB.4.0;Extended Properties="dBASE 5.0;'+';HDR=NO;DATABASE='+@path+'"'
--创建OLE
exec @err=sp_oacreate 'adodb.connection',@obj out
if @err<>0 goto lberr
exec @err=sp_oamethod @obj,'open',null,@constr
if @err<>0 begin goto lberr end
--生成DBF文件
set @sql='create table ['+@fname+']('+@cols+')'
exec @err=sp_oamethod @obj,'execute',@out out,@sql
print @sql
--关闭连接
exec @err=sp_oadestroy @obj
IF @err <> 0
BEGIN
EXEC sp_OAGetErrorInfo @obj
return
END
上面是主要代码,我执行前几次没有问题,后来就不行了,总是这样子,重启sql2000服务器又好了。
上面的代码也是在网上找的,可能是sp_oadestroy 没有关闭连接,但我不知道哪里有问题,请高手指点。
解决方案 »
- sql语句,分组统计表中所有字段信息
- 错误: errorCode=-1071636471 description=出现 OLE DB 错误。错误代码: 0x80004005。
- 怎么在select语句中加判断条件
- sql 2005 备份远程数据库到本地
- 有没有更好的办法来优化查询条件?
- 要点存储过程的例子看看
- 重装系统只剩下.dat(数据.dat,日志.dat)文件了,怎么恢复?
- 一个行列转换结构,100分求支招!!!!
- sql2008 r2 怎样实现判断字符串中包含小写字母
- Sql 行列转换 动态Sql(Pivot)
- SQL作业求解
- 想要两台SQL2005服务器间某个表的数据每日自动同步,哪种方法比较好?
create proc p_exporttb
@sqlstr varchar(8000), --要导出的查询名
@path nvarchar(1000), --文件存放目录
@fname nvarchar(250)='temp.dbf',--文件名,默认为temp
@over bit=0 --是否覆盖已经存在的文件,如果不覆盖,则直接追加
as
declare @err int,@src nvarchar(255),@desc nvarchar(255),@out int
declare @obj int,@constr nvarchar(1000),@sql varchar(8000),@fdlist varchar(8000)
--参数检测
if isnull(@fname,'')='' set @fname='temp.dbf'
--检查文件是否已经存在
if right(@path,1)<>'\' set @path=@path+'\'
create table #tb(a bit,b bit,c bit)
set @sql=@path+@fname
insert into #tb exec master..xp_fileexist @sql
if exists(select 1 from #tb where a=1)
if @over=1
begin
set @sql='del '+@sql
exec master..xp_cmdshell @sql,no_output
end
else
set @over=0
else
set @over=1
--数据库创建语句
set @sql=@path+@fname
set @constr='Provider=Microsoft.Jet.OLEDB.4.0;Extended Properties="dBASE 5.0;'
+';HDR=NO;DATABASE='+@path+'"'
--创建表的SQL
declare @tbname sysname
set @tbname='##tmp_'+convert(varchar(38),newid())
set @sql='select * into ['+@tbname+'] from('+@sqlstr+') a'
exec(@sql)
--连接数据库
exec @err=sp_oacreate 'adodb.connection',@obj out
if @err<>0 goto lberr
exec @err=sp_oamethod @obj,'open',null,@constr
if @err<>0 goto lberr
--创建表的SQL
select @sql='',@fdlist=''
select @fdlist=@fdlist+','+a.name
,@sql=@sql+',['+a.name+'] '
+case when b.name in('char','nchar','varchar','nvarchar') then
'text('+cast(case when a.length>250 then 250 else a.length end as varchar)+')'
when b.name in('tynyint','int','bigint','tinyint') then 'int'
when b.name in('smalldatetime','datetime') then 'datetime'
when b.name in('money','smallmoney') then 'money'
else b.name end
FROM tempdb..syscolumns a left join tempdb..systypes b on a.xtype=b.xusertype
where b.name not in('image','text','uniqueidentifier','sql_variant','ntext','varbinary','binary','timestamp')
and a.id=(select id from tempdb..sysobjects where name=@tbname)
select @sql='create table ['+@fname
+']('+substring(@sql,2,8000)+')'
,@fdlist=substring(@fdlist,2,8000)
if @over=1
begin
exec @err=sp_oamethod @obj,'execute',@out out,@sql
if @err<>0 goto lberr
end
exec @err=sp_oadestroy @obj
set @sql='openrowset(''MICROSOFT.JET.OLEDB.4.0'',''dBase 5.0;DATABASE='
+@path+''',''select * from ['+@fname+']'')'
--导入数据
exec('insert into '+@sql+'('+@fdlist+') select '+@fdlist+' from ['+@tbname+']')
set @sql='drop table ['+@tbname+']'
exec(@sql)
return
lberr:
exec sp_oageterrorinfo 0,@src out,@desc out
lbexit:
select cast(@err as varbinary(4)) as 错误号
,@src as 错误源,@desc as 错误描述
select @sql,@constr,@fdlist