求SQL语句

Question

数据库是SQl2005 一个表里内容是一个树状
怎么根据某个值,返回这个值子树的全部记录(包括本身,和所有子树的子树)举例:
如下表,ID不会相同,-1只有一个表示树的根:
ID PID PName
0 -1 A
1 0 B
2 0 C
3 1 D
4 3 A
5 2 F
...以ID条件查询
ID=0,结果:
返回所有ID=1,结果:
1 0 B
3 1 D
4 3 AID=2,结果:
2 0 C
5 2 F
...

Answer 1

原始数据及要求结果如下：
--食品 
  --水果 
    --香蕉 
    --苹果    
  --蔬菜 
    --青菜
id          pid         name                 
----------- ----------- -------------------- 
1           0           食品
2           1           水果
3           1           蔬菜
4           2           香蕉
5           2           苹果
6           3           青菜要求得到各节点的父路径即如下结果：
id  pid name  路径                         
--- --- ----- ---------------
1   0   食品  食品
2   1   水果  食品,水果
3   1   蔬菜  食品,蔬菜
4   2   香蕉  食品,水果,香蕉
5   2   苹果  食品,水果,苹果
6   3   青菜  食品,蔬菜,青菜 
*/create table tb (id int , pid int , name nvarchar(20)) 
insert into tb values(1 , 0 , '食品')
insert into tb values(2 , 1 , '水果')
insert into tb values(3 , 1 , '蔬菜')
insert into tb values(4 , 2 , '香蕉')
insert into tb values(5 , 2 , '苹果')
insert into tb values(6 , 3 , '青菜')
go--查询各节点的父路径函数
create function f_pid(@id int) returns varchar(100)
as
begin
  declare @re_str as varchar(100)
  set @re_str = ''
  select @re_str = name from tb where id = @id
  while exists (select 1 from tb where id = @id and pid <> 0)
    begin
      select @id = b.id , @re_str = b.name + ',' + @re_str from tb a , tb b where a.id = @id and a.pid = b.id
    end
  return @re_str
end
goselect * , dbo.f_pid(id) 路径 from tb order by iddrop table tb
drop function f_pid

Answer 2

sql2005的话现在没有测试环境， 应该跟这个一样的
--这里我使用书上的员工表
SET NOCOUNT ON;
USE tempdb;
GO
IF OBJECT_ID('dbo.Employees') IS NOT NULL
  DROP TABLE dbo.Employees;
GO
CREATE TABLE dbo.Employees
(
  empid   INT         NOT NULL PRIMARY KEY,
  mgrid   INT         NULL     REFERENCES dbo.Employees,
  empname VARCHAR(25) NOT NULL,
  salary  MONEY       NOT NULL,
  CHECK (empid <> mgrid)
);
INSERT INTO dbo.Employees(empid, mgrid, empname, salary)
  VALUES(1, NULL, 'David', $10000.00);
INSERT INTO dbo.Employees(empid, mgrid, empname, salary)
  VALUES(2, 1, 'Eitan', $7000.00);
INSERT INTO dbo.Employees(empid, mgrid, empname, salary)
  VALUES(3, 1, 'Ina', $7500.00);
INSERT INTO dbo.Employees(empid, mgrid, empname, salary)
  VALUES(4, 2, 'Seraph', $5000.00);
INSERT INTO dbo.Employees(empid, mgrid, empname, salary)
  VALUES(5, 2, 'Jiru', $5500.00);
INSERT INTO dbo.Employees(empid, mgrid, empname, salary)
  VALUES(6, 2, 'Steve', $4500.00);
INSERT INTO dbo.Employees(empid, mgrid, empname, salary)
  VALUES(7, 3, 'Aaron', $5000.00);
INSERT INTO dbo.Employees(empid, mgrid, empname, salary)
  VALUES(8, 5, 'Lilach', $3500.00);
INSERT INTO dbo.Employees(empid, mgrid, empname, salary)
  VALUES(9, 7, 'Rita', $3000.00);
INSERT INTO dbo.Employees(empid, mgrid, empname, salary)
  VALUES(10, 5, 'Sean', $3000.00);
INSERT INTO dbo.Employees(empid, mgrid, empname, salary)
  VALUES(11, 7, 'Gabriel', $3000.00);
INSERT INTO dbo.Employees(empid, mgrid, empname, salary)
  VALUES(12, 9, 'Emilia' , $2000.00);
INSERT INTO dbo.Employees(empid, mgrid, empname, salary)
  VALUES(13, 9, 'Michael', $2000.00);
INSERT INTO dbo.Employees(empid, mgrid, empname, salary)
  VALUES(14, 9, 'Didi', $1500.00);
--创建索引
CREATE UNIQUE INDEX idx_unc_mgrid_empid ON dbo.Employees(mgrid, empid);
go--SQL2000 udf方法：
IF OBJECT_ID('dbo.fn_subordinates1') IS NOT NULL
  DROP FUNCTION dbo.fn_subordinates1;
GO
CREATE FUNCTION dbo.fn_subordinates1(@root AS INT) 
RETURNS @Subs TABLE
(
  empid INT NOT NULL PRIMARY KEY NONCLUSTERED,
  lvl   INT NOT NULL,
  UNIQUE CLUSTERED(lvl, empid)  
)
AS
begin 
declare @lv int 
set @lv=0
insert @Subs values(@root,@lv)
while @@rowcount>0
begin 
    set @lv=@Lv+1;
    insert @subs
    select b.empid ,@Lv
    from @subs a join dbo.Employees b on a.empid=b.mgrid and lvl=@lv-1
end
return;
end 
go
SELECT empid, lvl FROM dbo.fn_subordinates1(3) AS S;--SQL2005 CTE
DECLARE @root AS INT;
SET @root = 3;
WITH SubsCTE
AS
(
  -- Anchor member returns root node
  SELECT empid, empname, 0 AS lvl
  FROM dbo.Employees
  WHERE empid = @root  UNION ALL  -- Recursive member returns next level of children
  SELECT C.empid, C.empname, P.lvl + 1
  FROM SubsCTE AS P
    JOIN dbo.Employees AS C
      ON C.mgrid = P.empid
)
SELECT * FROM SubsCTE;
/*
empid       empname                   lvl
----------- ------------------------- -----------
3           Ina                       0
7           Aaron                     1
9           Rita                      2
11          Gabriel                   2
12          Emilia                    3
13          Michael                   3
14          Didi                      3*/

Answer 3

;with cte as
(
select ID from tb where ID=0
union all 
select p.id from cte a join tb p on a.id=p.pid
)
select tb.* from cte a join tb on a.id=tb.id

Answer 4

create table tb(ID int, PID int, PName varchar(10))
insert tb select 
0 ,-1 ,'A' union all select  
1 ,0 ,'B' union all select  
2 ,0 ,'C' union all select  
3 ,1, 'D' union all select  
4 ,3, 'A' union all select  
5 ,2, 'F' ;with cte as
(
select ID from tb where ID=1
union all 
select p.id from cte a join tb p on a.id=p.pid
)
select tb.* from cte a join tb on a.id=tb.id
/*
ID          PID         PName
----------- ----------- ----------
1           0           B
3           1           D
4           3           A
*/

Answer 5

declare @id int
set @id=1
;with cte as
(
select ID,PID,pname from tb where ID=@id
union all 
select p.* from cte a join tb p on a.id=p.pid
)
select * from cte 
/*
ID          PID         PName
----------- ----------- ----------
1           0           B
3           1           D
4           3           A
*/
这样也可以 

Answer 6

结果出来了if object_id('[TB]') is not null drop table [TB]
go
create table [TB]([ID] int,[PID] int,[Name] varchar(1))
insert [TB]
select 0,-1,'A' union all
select 1,0,'B' union all
select 2,0,'C' union all
select 3,1,'D' union all
select 4,3,'A' union all
select 5,2,'F'
GOIF OBJECT_ID('dbo.fn_subordinates1') IS NOT NULL
  DROP FUNCTION dbo.fn_subordinates1;
GO
CREATE FUNCTION dbo.fn_subordinates1(@root AS INT) 
RETURNS @Subs TABLE
(
  id INT NOT NULL PRIMARY KEY NONCLUSTERED,
  lvl   INT NOT NULL,
  [name] nvarchar(1),
   pid int not null,
  UNIQUE CLUSTERED(lvl, id)  
)
AS
begin 
declare @lv int 
set @lv=0
insert @Subs
select @root,0, [name], a.pid
from dbo.tb a
where a.id = @root
while @@rowcount>0
begin 
    set @lv=@Lv+1;
    insert @subs
    select b.id ,@Lv, b.[name], b.pid
    from @subs a join dbo.tb b on a.id=b.PID and lvl=@lv-1
end
return;
end 
go
SELECT id, pid, name FROM dbo.fn_subordinates1(1) AS S;DROP FUNCTION fn_subordinates1
DROP TABLE TB
--测试结果:
/*
（所影响的行数为 6 行）id          pid         name 
----------- ----------- ---- 
1           0           B
3           1           D
4           3           A
*/

Answer 7

--sql 2000/*
标题：查询指定节点及其所有子节点的函数
作者：爱新觉罗·毓华(十八年风雨,守得冰山雪莲花开) 
时间：2008-05-12
地点：广东深圳
*/create table tb(id varchar(3) , pid varchar(3) , name varchar(10))
insert into tb values('001' , null  , '广东省')
insert into tb values('002' , '001' , '广州市')
insert into tb values('003' , '001' , '深圳市')
insert into tb values('004' , '002' , '天河区')
insert into tb values('005' , '003' , '罗湖区')
insert into tb values('006' , '003' , '福田区')
insert into tb values('007' , '003' , '宝安区')
insert into tb values('008' , '007' , '西乡镇')
insert into tb values('009' , '007' , '龙华镇')
insert into tb values('010' , '007' , '松岗镇')
go--查询指定节点及其所有子节点的函数
create function f_cid(@ID varchar(3)) returns @t_level table(id varchar(3) , level int)
as
begin
  declare @level int
  set @level = 1
  insert into @t_level select @id , @level
  while @@ROWCOUNT > 0
  begin
    set @level = @level + 1
    insert into @t_level select a.id , @level
    from tb a , @t_Level b
    where a.pid = b.id and b.level = @level - 1
  end
  return
end
go--调用函数查询001(广东省)及其所有子节点
select a.* from tb a , f_cid('001') b where a.id = b.id order by a.id
/*
id   pid  name       
---- ---- ---------- 
001  NULL 广东省
002  001  广州市
003  001  深圳市
004  002  天河区
005  003  罗湖区
006  003  福田区
007  003  宝安区
008  007  西乡镇
009  007  龙华镇
010  007  松岗镇（所影响的行数为 10 行）
*/--调用函数查询002(广州市)及其所有子节点
select a.* from tb a , f_cid('002') b where a.id = b.id order by a.id
/*
id   pid  name       
---- ---- ---------- 
002  001  广州市
004  002  天河区（所影响的行数为 2 行）
*/--调用函数查询003(深圳市)及其所有子节点
select a.* from tb a , f_cid('003') b where a.id = b.id order by a.id
/*
id   pid  name       
---- ---- ---------- 
003  001  深圳市
005  003  罗湖区
006  003  福田区
007  003  宝安区
008  007  西乡镇
009  007  龙华镇
010  007  松岗镇（所影响的行数为 7 行）
*/drop table tb
drop function f_cid@@ROWCOUNT：返回受上一语句影响的行数。
返回类型：integer。
注释：任何不返回行的语句将这一变量设置为 0 ，如 IF 语句。
示例：下面的示例执行 UPDATE 语句并用 @@ROWCOUNT 来检测是否有发生更改的行。UPDATE authors SET au_lname = 'Jones' WHERE au_id = '999-888-7777'
IF @@ROWCOUNT = 0
   print 'Warning: No rows were updated'结果：(所影响的行数为 0 行)
Warning: No rows were updated
--sql 2005
2005中获取该节点及其所有子节点的方法。(小梁)--> 生成测试数据: @T
DECLARE @T TABLE (BOM_NO INT,PRD_NO INT,NAME VARCHAR(5))
INSERT INTO @T
SELECT 123456,1234561,'测试1' UNION ALL
SELECT 123456,1234562,'测试2' UNION ALL
SELECT 1234561,1234563,'测试3' UNION ALL
SELECT 1234561,1234564,'测试4' UNION ALL
SELECT 123458,1234581,'测试5' UNION ALL
SELECT 123459,1234591,'测试6' UNION ALL
SELECT 123459,1234592,'测试7' UNION ALL
SELECT 1234564,12345641,'测试8'--SQL查询如下:DECLARE @BOM_NO INT
SET @BOM_NO=123456;WITH Liang AS
(
    SELECT 
        BOM_NO,PRD_NO,NAME,PATH=CAST(NAME AS VARCHAR(MAX))
    FROM @T
    WHERE BOM_NO=@BOM_NO
    UNION ALL
    SELECT
        A.BOM_NO,
        A.PRD_NO,
        A.NAME,
        B.PATH+'->'+A.NAME
    FROM @T AS A
        JOIN Liang AS B
            ON A.BOM_NO=B.PRD_NO
)
SELECT *
FROM Liang/*
BOM_NO      PRD_NO      NAME  PATH
----------- ----------- ----- ---------------------------------------
123456      1234561     测试1   测试1  
123456      1234562     测试2   测试2  
1234561     1234563     测试3   测试1->测试3    
1234561     1234564     测试4   测试1->测试4    
1234564     12345641    测试8   测试1->测试4->测试8      (5 行受影响)
*/

Answer 8

问下，是不是SQL server2000不支持树状啊。

Answer 9

sql2005支持cte
sql2000只能函数或存储过程