数据库 分页问题

Question

declare
@page int,--每页显示记录数
@num int,--查询页数
--@nowpage int,--当前页 @strsql varchar (200)
set  @page=10
set @num=5
set @strsql='select * from  (select ROW_NUMBER() OVER (order by spdm) as id,* from shangpin ) as temp '
if @num != 0
set @strsql=@strsql+' where id between '''@num''' and 20'
print @strsql
请问这个INT值怎么得到呢 ？

Answer 1

declare 
@page int,--每页显示记录数 
@num int,--查询页数 
--@nowpage int,--当前页 @strsql varchar (200) 
set  @page=10 
set @num=5 
set @strsql='select * from  (select ROW_NUMBER() OVER (order by spdm) as id,* from shangpin ) as temp ' 
if @num != 0 
set @strsql=@strsql+' where id between '+str(@num)+ 'and 20' 
print @strsql 

Answer 2

--===========================================================
--高效分页存储过程，仅适用于Sql2005
--===========================================================
set ANSI_NULLS ON 
set QUOTED_IDENTIFIER ON 
go 
-- ============================================= 
-- Description:    <高效分页存储过程，仅适用于Sql2005> 
-- Notes:        <排序字段强烈建议建索引> 
-- Page2005 'dyj_vclient','client_id,last_dt','client_id','last_dt','desc','',20,1,0 
-- ============================================= 
ALTER Procedure [dbo].[Page2005] 
@TableName varchar(50),          --表名 
@Fields varchar(5000) = '*',      --字段名(全部字段为*) 
@PrimaryKey varchar(20),          --主键 
@OrderField varchar(5000),        --排序字段(必须!支持多字段) 
@Orderby varchar(8)='desc',      --排序方式(desc：倒序，asc：顺序) 
@sqlWhere varchar(5000) = Null,  --条件语句(不用加where) 
@pageSize int,                    --每页多少条记录 
@pageIndex int = 1 ,              --指定当前为第几页 
@TotalPage int output            --返回总页数 
as 
begin 
    Begin Tran --开始事务 
    Declare @sql nvarchar(4000); 
    Declare @totalRecord int;    
    if isnull(@PrimaryKey,'')='' 
      set @PrimaryKey='*' 
    --计算总记录数 
        
    if (@SqlWhere='' or @sqlWhere=NULL) 
        set @sql = 'select @totalRecord = count('+ @PrimaryKey +') from ' + @TableName 
    else 
        set @sql = 'select @totalRecord = count('+ @PrimaryKey +') from ' + @TableName + ' where ' + @sqlWhere 
    EXEC sp_executesql @sql,N'@totalRecord int OUTPUT',@totalRecord OUTPUT--计算总记录数        
    
    --计算总页数 
    select @TotalPage=CEILING((@totalRecord+0.0)/@PageSize) 
    if (@SqlWhere='' or @sqlWhere=NULL) 
        set @sql = 'Select * FROM (select ROW_NUMBER() Over(order by ' + @OrderField + ' '+ @Orderby +') as rowId,' + @Fields + ' from ' + @TableName 
    else 
        set @sql = 'Select * FROM (select ROW_NUMBER() Over(order by ' + @OrderField + ' '+ @Orderby +') as rowId,' + @Fields + ' from ' + @TableName + ' where ' + @SqlWhere    
        
    
    --处理页数超出范围情况 
    if @PageIndex <=0 
        Set @pageIndex = 1 
    
    if @pageIndex>@TotalPage 
        Set @pageIndex = @TotalPage 
    --处理开始点和结束点 
    Declare @StartRecord int 
    Declare @EndRecord int 
    
    set @StartRecord = (@pageIndex-1)*@PageSize + 1 
    set @EndRecord = @StartRecord + @pageSize - 1 
    --继续合成sql语句 
    set @Sql = @Sql + ') as ' + @TableName + ' where rowId between ' + Convert(varchar(50),@StartRecord) + ' and ' +  Convert(varchar(50),@EndRecord) 
    
    Exec(@Sql) 
    --------------------------------------------------- 
    If @@Error <> 0 
      Begin 
        RollBack Tran 
        Return -1 
      End 
    Else 
      Begin 
        Commit Tran 
        Return @totalRecord ---返回记录总数 
      End    
end 

Answer 3

--=======================================================
--邹建
--=======================================================
-----------------------------------------------------------------------------------------------------
--TOP n 实现的通用分页存储过程(转自邹建)
CREATE PROC sp_PageView
@tbname     sysname,               --要分页显示的表名
@FieldKey   nvarchar(1000),      --用于定位记录的主键(惟一键)字段,可以是逗号分隔的多个字段
@PageCurrent int=1,               --要显示的页码
@PageSize   int=10,                --每页的大小(记录数)
@FieldShow nvarchar(1000)='',      --以逗号分隔的要显示的字段列表,如果不指定,则显示所有字段
@FieldOrder nvarchar(1000)='',      --以逗号分隔的排序字段列表,可以指定在字段后面指定DESC/ASC
                                          用于指定排序顺序
@Where    nvarchar(1000)='',     --查询条件
@PageCount int OUTPUT             --总页数
AS
SET NOCOUNT ON
--检查对象是否有效
IF OBJECT_ID(@tbname) IS NULL
BEGIN
    RAISERROR(N'对象"%s"不存在',1,16,@tbname)
    RETURN
END
IF OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsTable')=0
    AND OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsView')=0
    AND OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsTableFunction')=0
BEGIN
    RAISERROR(N'"%s"不是表、视图或者表值函数',1,16,@tbname)
    RETURN
END--分页字段检查
IF ISNULL(@FieldKey,N'')=''
BEGIN
    RAISERROR(N'分页处理需要主键（或者惟一键）',1,16)
    RETURN
END--其他参数检查及规范
IF ISNULL(@PageCurrent,0)<1 SET @PageCurrent=1
IF ISNULL(@PageSize,0)<1 SET @PageSize=10
IF ISNULL(@FieldShow,N'')=N'' SET @FieldShow=N'*'
IF ISNULL(@FieldOrder,N'')=N''
    SET @FieldOrder=N''
ELSE
    SET @FieldOrder=N'ORDER BY '+LTRIM(@FieldOrder)
IF ISNULL(@Where,N'')=N''
    SET @Where=N''
ELSE
    SET @Where=N'WHERE ('+@Where+N')'--如果@PageCount为NULL值,则计算总页数(这样设计可以只在第一次计算总页数,以后调用时,把总页数传回给存储过程,避免再次计算总页数,对于不想计算总页数的处理而言,可以给@PageCount赋值)
IF @PageCount IS NULL
BEGIN
    DECLARE @sql nvarchar(4000)
    SET @sql=N'SELECT @PageCount=COUNT(*)'
        +N' FROM '+@tbname
        +N' '+@Where
    EXEC sp_executesql @sql,N'@PageCount int OUTPUT',@PageCount OUTPUT
    SET @PageCount=(@PageCount+@PageSize-1)/@PageSize
END--计算分页显示的TOPN值
DECLARE @TopN varchar(20),@TopN1 varchar(20)
SELECT @TopN=@PageSize,
    @TopN1=(@PageCurrent-1)*@PageSize--第一页直接显示
IF @PageCurrent=1
    EXEC(N'SELECT TOP '+@TopN
        +N' '+@FieldShow
        +N' FROM '+@tbname
        +N' '+@Where
        +N' '+@FieldOrder)
ELSE
BEGIN
    --处理别名
    IF @FieldShow=N'*'
        SET @FieldShow=N'a.*'    --生成主键(惟一键)处理条件
    DECLARE @Where1 nvarchar(4000),@Where2 nvarchar(4000),
        @s nvarchar(1000),@Field sysname
    SELECT @Where1=N'',@Where2=N'',@s=@FieldKey
    WHILE CHARINDEX(N',',@s)>0
        SELECT @Field=LEFT(@s,CHARINDEX(N',',@s)-1),
            @s=STUFF(@s,1,CHARINDEX(N',',@s),N''),
            @Where1=@Where1+N' AND a.'+@Field+N'=b.'+@Field,
            @Where2=@Where2+N' AND b.'+@Field+N' IS NULL',
            @Where=REPLACE(@Where,@Field,N'a.'+@Field),
            @FieldOrder=REPLACE(@FieldOrder,@Field,N'a.'+@Field),
            @FieldShow=REPLACE(@FieldShow,@Field,N'a.'+@Field)
    SELECT @Where=REPLACE(@Where,@s,N'a.'+@s),
        @FieldOrder=REPLACE(@FieldOrder,@s,N'a.'+@s),
        @FieldShow=REPLACE(@FieldShow,@s,N'a.'+@s),
        @Where1=STUFF(@Where1+N' AND a.'+@s+N'=b.'+@s,1,5,N''),    
        @Where2=CASE
            WHEN @Where='' THEN N'WHERE ('
            ELSE @Where+N' AND ('
            END+N'b.'+@s+N' IS NULL'+@Where2+N')'    --执行查询
    EXEC(N'SELECT TOP '+@TopN
        +N' '+@FieldShow
        +N' FROM '+@tbname
        +N' a LEFT JOIN(SELECT TOP '+@TopN1
        +N' '+@FieldKey
        +N' FROM '+@tbname
        +N' a '+@Where
        +N' '+@FieldOrder
        +N')b ON '+@Where1
        +N' '+@Where2
        +N' '+@FieldOrder)
END

Answer 4

感谢各位的答案其实我就想要个简单的 想理下直接的思路，请问这么来获取当前页呢即怎么来读取@numpage 的值呢 ？目的在于程序中点下一页时可以执行到@numpage +1--drop proc pagetest1--exec pagetest1 10,3,'下一页'
go
create proc pagetest1
@pagesize int,--分页大小
@numpage int,--查询页数
@nowpage varchar (10)--下一页或者上一页 为空表示当前页as
declare
@strsql varchar (200)
--set  @pagesize=10
--set @numpage=5
set @strsql='select * from  (select ROW_NUMBER() OVER (order by spdm) as id,* from shangpin ) as temp '
 if  @numpage != 0 and @nowpage=''
begin
set @strsql=@strsql+' where id between '+str((@numpage-1)*@pagesize+1)+' and '+str((@numpage)*@pagesize)
end else if --@numpage != 0 and
 @nowpage='上一页'
begin
set @strsql=@strsql+' where id between '+str((@numpage-1-1)*@pagesize+1)+' and '+str((@numpage-1)*@pagesize)
end else
begin
set @strsql=@strsql+' where id between '+str((@numpage-1+1)*@pagesize+1)+' and '+str((@numpage+1)*@pagesize)
end
--end
print @strsql
--print @unmpage
exec (@strsql)
go