求教SQL，得到每个分组的前N条记录

Question

测试数据
--------------------------------------
类别      名称               数量      版号
kind       name          num      pg_sn
K金类    G750金氧化锆手链   2        a
K金类    G750金氧化锆手链   1        b
K金类    G750金氧化锆手链   1         c
K金类    G750金氧化锆手链   1         d
珠宝类   G750氧化锆手链   1        e
珠宝类   G750氧化锆手链    1       f
珠宝类   G750氧化锆手链    2        g
珠宝类   G750氧化锆手链    2      h
珠宝类   G750氧化锆手链    1      y
珠宝类   G750氧化锆手链    1      q
珠宝类   G750氧化锆手链    1      w
珠宝类   G750氧化锆手链    1        z
-------------------------------------
假如现在要得到每个分组的前2条记录
结果如下：
kind       name          num       pg_sn
K金类    G750金氧化锆手链   2         a
K金类    G750金氧化锆手链   1         b
珠宝类   G750氧化锆手链    2        g
珠宝类   G750氧化锆手链    2        h

Answer 1

SET NOCOUNT ON
IF OBJECT_ID('TEMPDB..#')IS NOT NULL DROP TABLE  #
GO
CREATE TABLE #(kind NVARCHAR(10),      name  NVARCHAR(20),         num  INT,     pg_sn VARCHAR(10)) 
INSERT # SELECT N'K金类'   , N'G750金氧化锆手链' ,  2 ,       'a' 
INSERT # SELECT N'K金类'   , N'G750金氧化锆手链' ,  1 ,       'b' 
INSERT # SELECT N'K金类'   , N'G750金氧化锆手链' ,  1 ,       'c' 
INSERT # SELECT N'K金类'   , N'G750金氧化锆手链' ,  1,        'd' 
INSERT # SELECT N'珠宝类'  ,N'G750氧化锆手链' ,  1   ,     'e' 
INSERT # SELECT N'珠宝类'  ,N'G750氧化锆手链' ,  1   ,   'f' 
INSERT # SELECT N'珠宝类' , N'G750氧化锆手链',   2  ,      'g' 
INSERT # SELECT N'珠宝类',  N'G750氧化锆手链',   2 ,     'h' 
INSERT # SELECT N'珠宝类',  N'G750氧化锆手链',   1 ,     'y' 
INSERT # SELECT N'珠宝类',  N'G750氧化锆手链',   1 ,     'q' 
INSERT # SELECT N'珠宝类',  N'G750氧化锆手链',   1 ,     'w' 
INSERT # SELECT N'珠宝类',  N'G750氧化锆手链' ,  1 ,       'z' 
IF OBJECT_ID('TEMPDB..#T')IS NOT NULL DROP TABLE #T
GO
SELECT ID=IDENTITY(INT,1,1),* INTO #T FROM #
SELECT * FROM #T  T WHERE  CHECKSUM(*) IN (SELECT TOP 2  CHECKSUM(*) FROM #T WHERE kind=T.kind ORDER BY ID  )
/*ID          kind       name                 num         pg_sn      
----------- ---------- -------------------- ----------- ---------- 
1           K金类        G750金氧化锆手链           2           a
2           K金类        G750金氧化锆手链           1           b
5           珠宝类        G750氧化锆手链            1           e
6           珠宝类        G750氧化锆手链            1           f
*/

Answer 2

问题：1.可以不用临时表来处理不？
      2.CHECKSUM(*)这个是什么意思？我用的是（SQL SERVER 2000）

Answer 3

DECLARE @TB TABLE( kind NVARCHAR(5),      name NVARCHAR(10),         num INT,      pg_sn  VARCHAR(2),ID INT IDENTITY(1,1))
INSERT @TB
SELECT N'K金类',  N'G750金氧化锆手链',  2,  'a' UNION ALL 
SELECT N'K金类',  N'G750金氧化锆手链',  1,  'b' UNION ALL 
SELECT N'K金类',  N'G750金氧化锆手链',  1,  'c' UNION ALL 
SELECT N'K金类',  N'G750金氧化锆手链',  1,  'd' UNION ALL 
SELECT N'珠宝类',  N'G750氧化锆手链',  1,  'e' UNION ALL 
SELECT N'珠宝类',  N'G750氧化锆手链',  1,  'f' UNION ALL 
SELECT N'珠宝类',  N'G750氧化锆手链',  2,  'g' UNION ALL 
SELECT N'珠宝类',  N'G750氧化锆手链',  2,  'h' UNION ALL 
SELECT N'珠宝类',  N'G750氧化锆手链',  1,  'y' UNION ALL 
SELECT N'珠宝类',  N'G750氧化锆手链',  1,  'q' UNION ALL 
SELECT N'珠宝类',  N'G750氧化锆手链',  1,  'w' UNION ALL 
SELECT N'珠宝类',  N'G750氧化锆手链',  1,  'z'SELECT kind,name,num,pg_sn
FROM (
SELECT *,SEQ=ID-(SELECT COUNT(*) FROM @TB WHERE kind<A.kinD) FROM @TB AS A) T
WHERE SEQ<=2
/*
kind  name       num         pg_sn 
----- ---------- ----------- ----- 
K金类   G750金氧化锆手链 2           a
K金类   G750金氧化锆手链 1           b
珠宝类   G750氧化锆手链  1           e
珠宝类   G750氧化锆手链  1           f
*/

Answer 4

DECLARE @TB TABLE( kind NVARCHAR(5),      name NVARCHAR(10),         num INT,      pg_sn  VARCHAR(2))
INSERT @TB
SELECT N'K金类',  N'G750金氧化锆手链',  2,  'a' UNION ALL 
SELECT N'K金类',  N'G750金氧化锆手链',  1,  'b' UNION ALL 
SELECT N'K金类',  N'G750金氧化锆手链',  1,  'c' UNION ALL 
SELECT N'K金类',  N'G750金氧化锆手链',  1,  'd' UNION ALL 
SELECT N'珠宝类',  N'G750氧化锆手链',  1,  'e' UNION ALL 
SELECT N'珠宝类',  N'G750氧化锆手链',  1,  'f' UNION ALL 
SELECT N'珠宝类',  N'G750氧化锆手链',  2,  'g' UNION ALL 
SELECT N'珠宝类',  N'G750氧化锆手链',  2,  'h' UNION ALL 
SELECT N'珠宝类',  N'G750氧化锆手链',  1,  'y' UNION ALL 
SELECT N'珠宝类',  N'G750氧化锆手链',  1,  'q' UNION ALL 
SELECT N'珠宝类',  N'G750氧化锆手链',  1,  'w' UNION ALL 
SELECT N'珠宝类',  N'G750氧化锆手链',  1,  'z'SELECT kind,name,num,pg_sn
FROM @TB  AS A WHERE (SELECT COUNT(*) FROM @TB WHERE kind=A.kind AND pg_sn<A.pg_sn)<2/*
kind  name       num         pg_sn 
----- ---------- ----------- ----- 
K金类   G750金氧化锆手链 2           a
K金类   G750金氧化锆手链 1           b
珠宝类   G750氧化锆手链  1           e
珠宝类   G750氧化锆手链  1           f
*/

Answer 5

create table #t
(
 kind nvarchar(20), 
 name nvarchar(20),
 num int,
 pg_sn nvarchar(20) 
)
insert into #t
select 
'K金类',    'G750金氧化锆手链',   2,        'a'  union all
select 'K金类' ,   'G750金氧化锆手链',   1,        'b' union all 
select 'K金类' ,   'G750金氧化锆手链',   1,        'c'  union all
select 'K金类' ,  'G750金氧化锆手链',   1 ,      'd' union all
select '珠宝类',  'G750氧化锆手链',   1 ,       'e' union all
select '珠宝类',  'G750氧化锆手链',   1 ,     'f' union all
select '珠宝类',  'G750氧化锆手链',   2 ,       'g' union all
select '珠宝类',  'G750氧化锆手链',   2 ,     'h' union all
select '珠宝类',  'G750氧化锆手链',   1 ,     'y' union all
select '珠宝类',  'G750氧化锆手链',   1 ,     'q' union all
select '珠宝类',  'G750氧化锆手链',   1 ,     'w' union all
select '珠宝类',  'G750氧化锆手链',   1 ,     'z' 
select kind,name,num,pg_sn from
(select kind,name,num,pg_sn,ROW_NUMBER() over(partition by kind order by num DESC) rank1
from #t) A
where A.rank1 in(1,2)

Answer 6

ALTER TABLE TB 
ADD ID INT IDENTITY
GO
--查詢
GO
ALTER TABLE TB 
DROP COLUMN ID

Answer 7

select a.* from tblName a
left join tblcdkGroup b on a.typeid=b.typeid and a.groupid>=b.groupid
group by a.*
having count(b.Groupid) <=2 ;

Answer 8

select t1.* from #t t1 where pg_sn in (select top 2 pg_sn from #t t2 where t1.kind=t2.kind and t1.name=t2.name order by num desc,pg_sn)
这样?

Answer 9

---------------------------------
--  Author: liangCK 小梁
--  Title : 查每个分组前N条记录
--  Date  : 2008-11-13 17:19:23
---------------------------------
 
--> 生成测试数据: #T
IF OBJECT_ID('tempdb.dbo.#T') IS NOT NULL DROP TABLE #T
CREATE TABLE #T (ID VARCHAR(3),GID INT,Author VARCHAR(29),Title VARCHAR(39),Date DATETIME)
INSERT INTO #T
SELECT '001',1,'邹建','深入浅出SQLServer2005开发管理与应用实例','2008-05-10' UNION ALL
SELECT '002',1,'胡百敬','SQLServer2005性能调校','2008-03-22' UNION ALL
SELECT '003',1,'格罗夫Groff.J.R.','SQL完全手册','2009-07-01' UNION ALL
SELECT '004',1,'KalenDelaney','SQLServer2005技术内幕存储引擎','2008-08-01' UNION ALL
SELECT '005',2,'Alex.Kriegel.Boris.M.Trukhnov','SQL宝典','2007-10-05' UNION ALL
SELECT '006',2,'飞思科技产品研发中心','SQLServer2000高级管理与开发','2007-09-10' UNION ALL
SELECT '007',2,'胡百敬','SQLServer2005数据库开发详解','2008-06-15' UNION ALL
SELECT '008',3,'陈浩奎','SQLServer2000存储过程与XML编程','2005-09-01' UNION ALL
SELECT '009',3,'赵松涛','SQLServer2005系统管理实录','2008-10-01' UNION ALL
SELECT '010',3,'黄占涛','SQL技术手册','2006-01-01'--SQL查询如下:--按GID分组,查每个分组中Date最新的前2条记录
--1.字段ID唯一时:
SELECT * FROM #T AS T WHERE ID IN(SELECT TOP 2 ID FROM #T WHERE GID=T.GID ORDER BY Date DESC)--2.如果ID不唯一时:
SELECT * FROM #T AS T WHERE 2>(SELECT COUNT(*) FROM #T WHERE GID=T.GID AND Date>T.Date)--SQL Server 2005 使用新方法--3.使用ROW_NUMBER()进行排位分组
SELECT ID,GID,Author,Title,Date
FROM
(
   SELECT rid=ROW_NUMBER() OVER(PARTITION BY GID ORDER BY Date DESC),*
   FROM #T
) AS T
WHERE rid<=2--4.使用APPLY
SELECT DISTINCT b.*
FROM #T AS a
CROSS APPLY
(
    SELECT TOP(2) * FROM #T WHERE a.GID=GID ORDER BY Date DESC
) AS b
--结果
/*ID   GID         Author                        Title                                   Date
---- ----------- ----------------------------- --------------------------------------- -----------------------
003  1           格罗夫Groff.J.R.                 SQL完全手册                                 2009-07-01 00:00:00.000
004  1           KalenDelaney                  SQLServer2005技术内幕存储引擎                   2008-08-01 00:00:00.000
005  2           Alex.Kriegel.Boris.M.Trukhnov SQL宝典                                   2007-10-05 00:00:00.000
007  2           胡百敬                           SQLServer2005数据库开发详解                    2008-06-15 00:00:00.000
009  3           赵松涛                           SQLServer2005系统管理实录                     2008-10-01 00:00:00.000
010  3           黄占涛                           SQL技术手册                                 2006-01-01 00:00:00.000(6 行受影响)
*/

Answer 10

SELECT kind,name,num,pg_sn
FROM @TB  AS A WHERE (SELECT COUNT(*) FROM @TB WHERE kind=A.kind AND pg_sn<A.pg_sn)<2 中WHERE kind=A.kind AND pg_sn<A.pg_sn我搞不懂是什么意思，能详细解释下么？

Answer 11

根据where条件UOION就可以了