一个sql查询问题。字段内查询

Question

id   author
1     施海仙
2     施海仙，余斌
3     余斌类似这样的一张表
现在的查询语句是
Select *  from ResearchReport  where Author in ('施海仙','余斌')
但 第二条记录就查询不出，我想全部能查询出来，这样的语句不知道怎么写。
请各位帮忙！！！！

Answer 1

是在Sql Server 2000里的查询

Answer 2

CREATE  TABLE TB(id INT,  author NVARCHAR(10))
INSERT TB
SELECT 1,  N'施海仙' UNION ALL 
SELECT 2,  N'施海仙,余斌' UNION ALL 
SELECT 3,  N'余斌'SELECT TOP 100 ID=IDENTITY(INT,1,1) INTO # FROM SYSCOLUMNSSELECT A.* FROM 
(
SELECT DISTINCT ID
FROM (
SELECT A.ID,SUBSTRING(author, T.ID, CHARINDEX(',', AUTHOR+',', T.ID)-T.ID) AS AUTHOR
FROM TB AS A,# AS T
WHERE CHARINDEX(',', ','+author,T.ID)=T.ID
) T
WHERE  AUTHOR IN ('施海仙','余斌')
) B JOIN TB AS A ON A.ID=B.IDDROP TABLE TB
DROP TABLE #
/*
id          author     
----------- ---------- 
1           施海仙
2           施海仙,余斌
3           余斌
*/

Answer 3

create table t(id int,author varchar(40))
insert into t values(1,'施海仙')
insert into t values(2,'施海仙，余斌')
insert into t values(2,'施海仙1，余斌1')
insert into t values(2,'施海仙2，余斌2')
insert into t values(3,'余斌') 
gocreate function f_str(@str1 varchar(40),@str2 varchar(40))
returns int
as
begin
    declare @str3 varchar(40)    select @str1=@str1+'，', @str2='，'+@str2+'，'
    
    while charindex('，',@str1)>0
    begin
        select @str3=left(@str1,charindex('，',@str1)),
               @str1=stuff(@str1,1,charindex('，',@str1),'')
        
        if charindex('，'+@str3,@str2)>0
            return 1
    end
    return 0
end
go
select * from t where dbo.f_str(author,'施海仙，余斌')=1/*
id          author                                   
----------- ---------------------------------------- 
1           施海仙
2           施海仙，余斌
3           余斌
*/
godrop function f_str
drop table t
go

Answer 4

select * from ResearchReport where Author like '%施海仙%' or Author like '%余斌%' 

Answer 5

create table tb(id int,author varchar(40))
insert into tb values(1,'施海仙')
insert into tb values(2,'施海仙，余斌')
insert into tb values(3,'余斌') 
goselect * from tb where Author like '%施海仙%' or Author like '%余斌%' drop table tb/*
id          author                                   
----------- ---------------------------------------- 
1           施海仙
2           施海仙，余斌
3           余斌（所影响的行数为 3 行）
*/

Answer 6

--其他相关内容请参考:
/*
标题：分解字符串并查询相关数据
作者：爱新觉罗.毓华(十八年风雨,守得冰山雪莲花开) 
时间：2008-03-18
地点：广东深圳
说明：通过使用函数等方法分解字符串查询相关数据。问题：通过分解一个带某种符号分隔的字符串在数据库中查找相关数据。
例如 @str = '1,2,3',查询下表得到记录1,4,5,6
ID TypeID
1  1,2,3,4,5,6,7,8,9,10,11,12
2  2,3 
3  3,7,8,9 
4  2,6 
5  4,5
6  6,7 
*/
-----------------------------
create table tb (ID int , TypeID varchar(30)) 
insert into tb values(1 , '1,2,3,4,5,6,7,8,9,10,11,12') 
insert into tb values(2 , '2,3') 
insert into tb values(3 , '3,7,8,9') 
insert into tb values(4 , '2,6') 
insert into tb values(5 , '4,5')
insert into tb values(6 , '6,7')
go
-----------------------------
--如果仅仅是一个,如@str = '1'.
declare @str as varchar(30)
set @str = '1'
select * from tb where charindex(',' + @str + ',' , ',' + TypeID + ',') > 0
select * from tb where ',' + TypeID + ',' like '%,' + @str + ',%'
/*
ID          TypeID                         
----------- ------------------------------ 
1           1,2,3,4,5,6,7,8,9,10,11,12
（所影响的行数为 1 行）
*/-----------------------------
--如果包含两个,如@str = '1,2'.
declare @str as varchar(30)
set @str = '1,2'
select * from tb where charindex(',' + left(@str , charindex(',' , @str) - 1) + ',' , ',' + typeid + ',') > 0 or 
  charindex(',' + substring(@str , charindex(',' , @str) + 1 , len(@str)) + ',' , ',' + typeid + ',') > 0
select * from tb where ',' + typeid + ',' like '%,' + left(@str , charindex(',' , @str) - 1) + ',%' or 
  ',' + typeid + ',' like '%,' + substring(@str , charindex(',' , @str) + 1 , len(@str)) + ',%'
/*
ID          TypeID                         
----------- ------------------------------ 
1           1,2,3,4,5,6,7,8,9,10,11,12
2           2,3
4           2,6
（所影响的行数为 3 行）
*/-------------------------------------------
--如果包含三个或四个，用PARSENAME函数来处理.
declare @str as varchar(30)
set @str = '1,2,3,4'
select * from tb where 
  charindex(',' + parsename(replace(@str , ',' , '.') , 4) + ',' , ',' + typeid + ',') > 0 or
  charindex(',' + parsename(replace(@str , ',' , '.') , 3) + ',' , ',' + typeid + ',') > 0 or
  charindex(',' + parsename(replace(@str , ',' , '.') , 2) + ',' , ',' + typeid + ',') > 0 or
  charindex(',' + parsename(replace(@str , ',' , '.') , 1) + ',' , ',' + typeid + ',') > 0 
select * from tb where 
  ',' + typeid + ',' like '%,' + parsename(replace(@str , ',' , '.') , 4) + ',%' or
  ',' + typeid + ',' like '%,' + parsename(replace(@str , ',' , '.') , 3) + ',%' or
  ',' + typeid + ',' like '%,' + parsename(replace(@str , ',' , '.') , 2) + ',%' or
  ',' + typeid + ',' like '%,' + parsename(replace(@str , ',' , '.') , 1) + ',%'
/*
ID          TypeID                         
----------- ------------------------------ 
1           1,2,3,4,5,6,7,8,9,10,11,12
2           2,3
3           3,7,8,9
4           2,6
5           4,5
（所影响的行数为 5 行）
*/---------------------------------------
--如果超过四个，则只能使用函数或动态SQL来分解并查询数据。
/*
名称：fn_split函数.
功能：实现字符串分隔功能的函数
*/
create function dbo.fn_split(@inputstr varchar(8000), @seprator varchar(10))
returns @temp table (a varchar(200))
as 
begin
  declare @i int
  set @inputstr = rtrim(ltrim(@inputstr))
  set @i = charindex(@seprator , @inputstr)
  while @i >= 1
  begin
    insert @temp values(left(@inputstr , @i - 1))
    set @inputstr = substring(@inputstr , @i + 1 , len(@inputstr) - @i)
    set @i = charindex(@seprator , @inputstr)
  end
  if @inputstr <> '\'
  insert @temp values(@inputstr)
  return 
end
go--调用
declare @str as varchar(30)
set @str = '1,2,3,4,5'select distinct m.* from tb m,
(select * from dbo.fn_split(@str,',')) n
where charindex(',' + n.a + ',' , ',' + m.typeid + ',') > 0drop table tb
drop function dbo.fn_split /*
ID          TypeID                         
----------- ------------------------------ 
1           1,2,3,4,5,6,7,8,9,10,11,12
2           2,3
3           3,7,8,9
4           2,6
5           4,5
（所影响的行数为 5 行）
*/------------------------------------------
--使用动态SQL的语句。
declare @str varchar(200)
declare @sql as varchar(1000)
set @str = '1,2,3,4,5'
set @sql = 'select ''' + replace(@str , ',' , ''' as id union all select ''')
set @sql = @sql + ''''
set @sql = 'select distinct a.* from tb a , (' + @sql + ') b where charindex(' + ''','' + b.id + ' + ''',''' + ' , ' + ''','' + a.typeid + ' + ''',''' + ') > 0 '
exec (@sql)
/*
ID          TypeID                         
----------- ------------------------------ 
1           1,2,3,4,5,6,7,8,9,10,11,12
2           2,3
3           3,7,8,9
4           2,6
5           4,5
（所影响的行数为 5 行）
*/

Answer 7

Select *  from ResearchReport  
where charindex('，施海仙，','，'+Author+'，')>0
or charindex('，余斌，','，'+Author+'，')>0

Answer 8

要求不高的场合,这样就可以了:
select * from mydbtb where name like '%施海仙%' or name like '%余斌%'