递归结构的表，如何按顺序返回所有的父类和之类

Question

表结构如下：
ID___PID___mName___mUrl___mOrder
CREATE TABLE [dbo].[uMenuData](
[ID] [int] IDENTITY(1,1) NOT NULL,
[PID] [int] NULL,
[mName] [nvarchar](255) COLLATE Chinese_PRC_CI_AS NULL,
[mURL] [nvarchar](255) COLLATE Chinese_PRC_CI_AS NULL,
[mOrder] [int] NULL,
[mPermission] [nvarchar](255) COLLATE Chinese_PRC_CI_AS NULL
) ON [PRIMARY]
PID是父ID，指向ID如何按照这样的顺序列出所有的项（父项和子项）
父项一
父项一子项一
父项一子项二
父项二
父项二子项一
父项二子项二另外就是给定一个父项ID是，列出这个父项和他的所有子项？
函数和存储过程都可以，越简单越好，如果一句就能实现最好，不要写的太复杂（偶很菜滴～）

Answer 1

/*
标题：查询指定节点及其所有子节点的函数
作者：爱新觉罗.毓华(十八年风雨,守得冰山雪莲花开) 
时间：2008-05-12
地点：广东深圳
*/create table tb(id varchar(3) , pid varchar(3) , name varchar(10))
insert into tb values('001' , null  , '广东省')
insert into tb values('002' , '001' , '广州市')
insert into tb values('003' , '001' , '深圳市')
insert into tb values('004' , '002' , '天河区')
insert into tb values('005' , '003' , '罗湖区')
insert into tb values('006' , '003' , '福田区')
insert into tb values('007' , '003' , '宝安区')
insert into tb values('008' , '007' , '西乡镇')
insert into tb values('009' , '007' , '龙华镇')
insert into tb values('010' , '007' , '松岗镇')
go--查询指定节点及其所有子节点的函数
create function f_cid(@ID varchar(3)) returns @t_level table(id varchar(3) , level int)
as
begin
  declare @level int
  set @level = 1
  insert into @t_level select @id , @level
  while @@ROWCOUNT > 0
  begin
    set @level = @level + 1
    insert into @t_level select a.id , @level
    from tb a , @t_Level b
    where a.pid = b.id and b.level = @level - 1
  end
  return
end
go--调用函数查询001(广东省)及其所有子节点
select a.* from tb a , f_cid('001') b where a.id = b.id order by a.id
/*
id   pid  name       
---- ---- ---------- 
001  NULL 广东省
002  001  广州市
003  001  深圳市
004  002  天河区
005  003  罗湖区
006  003  福田区
007  003  宝安区
008  007  西乡镇
009  007  龙华镇
010  007  松岗镇（所影响的行数为 10 行）
*/--调用函数查询002(广州市)及其所有子节点
select a.* from tb a , f_cid('002') b where a.id = b.id order by a.id
/*
id   pid  name       
---- ---- ---------- 
002  001  广州市
004  002  天河区（所影响的行数为 2 行）
*/--调用函数查询003(深圳市)及其所有子节点
select a.* from tb a , f_cid('003') b where a.id = b.id order by a.id
/*
id   pid  name       
---- ---- ---------- 
003  001  深圳市
005  003  罗湖区
006  003  福田区
007  003  宝安区
008  007  西乡镇
009  007  龙华镇
010  007  松岗镇（所影响的行数为 7 行）
*/drop table tb
drop function f_cid

Answer 2

create function f_cid(@ID int) returns @t_level table(id int , level int)
as
begin
  declare @level int
  set @level = 1
  insert into @t_level select @id , @level
  while @@ROWCOUNT > 0
  begin
    set @level = @level + 1
    insert into @t_level select a.id , @level
    from tb a , @t_Level b
    where a.pid = b.id and b.level = @level - 1
  end
  return
end
go
只需要改个类型就行了.字段名都是一样的.

Answer 3

如果是2005,可以用下面的CREATE TABLE [dbo].[uMenuData](
    [ID] [int] IDENTITY(1,1) NOT NULL,
    [PID] [int] NULL,
    [mName] [nvarchar](255) COLLATE Chinese_PRC_CI_AS NULL,
    [mURL] [nvarchar](255) COLLATE Chinese_PRC_CI_AS NULL,
    [mOrder] [int] NULL,
    [mPermission] [nvarchar](255) COLLATE Chinese_PRC_CI_AS NULL
) ON [PRIMARY]
SET IDENTITY_INSERT [uMenuData] ON
GO
INSERT INTO [uMenuData]([ID],[PID],[mName])
SELECT 1,NULL,'A' UNION ALL
SELECT 2,1,'A-1' UNION ALL
SELECT 3,1,'A-2' UNION ALL
SELECT 4,2,'A-1-1' UNION ALL
SELECT 5,3,'A-2-1' UNION ALL
SELECT 6,4,'A-1-1-1' UNION ALL
SELECT 7,NULL,'B' UNION ALL
SELECT 8,7,'B-1' UNION ALL
SELECT 9,7,'B-2'
GO
SET IDENTITY_INSERT [uMenuData] OFF
GO-- 按照顺获取所有的项
;WITH TEMP_CTE
AS
(
        SELECT  *,CAST(ID AS VARCHAR(100)) AS Path 
          FROM  uMenuData
         WHERE  PID IS NULL
         UNION  ALL
        SELECT  A.*,CAST(Path + ','+ CAST(A.ID AS VARCHAR(100)) AS VARCHAR(100)) AS Path 
          FROM  uMenuData A
         INNER  JOIN TEMP_CTE B ON B.ID = A.PID
)
SELECT * FROM TEMP_CTE ORDER BY Path;GO--给定一个父项ID是，列出这个父项和他的所有子项
DECLARE @ID     INT
SET @ID = 1;WITH TEMP1
AS
(
        SELECT  * FROM uMenuData WHERE ID = @ID
        UNION ALL
        SELECT  B.* FROM TEMP1 A INNER JOIN uMenuData B ON A.ID = B.PID
)
SELECT * FROM TEMP1
-- DROP TABLE [uMenuData]

Answer 4

select a.id as aid,b.id as bid,a.pid,b.mname from uMenuData a inner join (select * uMenuData tb) b on a.ID=b.PID不知道这样可以不可以