□□■■问一个关于 备份/恢复 的简单的问题! ■■□□

Question

示例
A. 备份整个 MyNwind 数据库
说明  MyNwind 数据库仅用于演示。
下例创建用于存放 MyNwind 数据库完整备份的逻辑备份设备。-- Create a logical backup device for the full MyNwind backup.(先建立备份设备)
USE master
EXEC sp_addumpdevice 'disk', 'MyNwind_1', 
   DISK ='c:\Program Files\Microsoft SQL Server\MSSQL\BACKUP\MyNwind_1.dat'-- Back up the full MyNwind database.（然后再进行备份）
BACKUP DATABASE MyNwind TO MyNwind_1 

Answer 1

楼上的，楼主都特别强调说是备份/恢复 自定义选择 路径，可你强奸别人到 
DISK ='c:\Program Files\Microsoft SQL Server\MSSQL\BACKUP\MyNwind_1.dat'汗...

Answer 2

http://www.programfan.com/showarticle.asp?id=2472VB实现SQL Server数据库备份/恢复 '*************************************************************************
'**模 块 名：fBackupDatabase_a
'**描    述：备份数据库,返回出错信息,正常恢复,返回""
'**调    用：fBackupDatabase_a "备份文件名","数据库名"
'**参数说明：
'**          sBackUpfileName  恢复后的数据库存放目录
'**          sDataBaseName    备份的数据名
'**          sIsAddBackup     是否追加到备份文件中
'**说    明：引用Microsoft ActiveX Data Objects 2.x Library
'**创 建 人：邹建
'**日    期：2003年12月09日
'*************************************************************************
Public Function fBackupDatabase_a(ByVal sBackUpfileName$ _
                                , ByVal sDataBaseName$ _
                                , Optional ByVal sIsAddBackup As Boolean = False _
                                ) As String
                                
    Dim iDb As ADODB.Connection
    Dim iConcStr$, iSql$, iReturn$
    
    On Error GoTo lbErr
    
    '创建对象
    Set iDb = New ADODB.Connection
    
    '连接数据库服务器,根据你的情况修改连接字符串
    iConcStr = "Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security Info=False;Data Source=zj"
    iDb.Open iConcStr
    
    '生成数据库备份语句
    iSql = "backup database [" & sDataBaseName & "]" & vbCrLf & _
            "to disk='" & sBackUpfileName & "'" & vbCrLf & _
            "with description='" & "zj-backup at:" & Date & "(" & Time & ")'" & vbCrLf & _
            IIf(sIsAddBackup, "", ",init")
            
    iDb.Execute iSql
    GoTo lbExit
    
lbErr:
    iReturn = Error
lbExit:
    fBackupDatabase_a = iReturn
End Function'*************************************************************************
'**模 块 名：frestoredatabase_a
'**描    述：恢复数据库,返回出错信息,正常恢复,返回""
'**调    用：frestoredatabase_a "备份文件名","数据库名"
'**参数说明：
'**          sDataBasePath  恢复后的数据库存放目录
'**          sBackupNumber  是从那个备份号恢复
'**          sReplaceExist  指定是否覆盖已经存在的数据
'**说    明：引用Microsoft ActiveX Data Objects 2.x Library
'**创 建 人：邹建
'**日    期：2003年12月09日
'*************************************************************************
Public Function fRestoreDatabase_a(ByVal sBackUpfileName$ _
                                , ByVal sDataBaseName$ _
                                , Optional ByVal sDataBasePath$ = "" _
                                , Optional ByVal sBackupNumber& = 1 _
                                , Optional ByVal sReplaceExist As Boolean = False _
                                ) As String
    
    Dim iDb As ADODB.Connection, iRe As ADODB.Recordset
    Dim iConcStr$, iSql$, iReturn$, iI&
    
    On Error GoTo lbErr
    
    '创建对象
    Set iDb = New ADODB.Connection
    Set iRe = New ADODB.Recordset
    
    '连接数据库服务器,根据你的情况修改连接字符串
    iConcStr = "Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security Info=False;Data Source=zj"
    iDb.Open iConcStr
    
    '得到还原后的数据库存放目录,如果没有指定,存放到SQL SERVER的DATA目录
    If sDataBasePath = "" Then
        iSql = "select filename from master..sysfiles"
        iRe.Open iSql, iDb, adOpenKeyset, adLockReadOnly
        iSql = iRe(0)
        iRe.Close
        sDataBasePath = Left(iSql, InStrRev(iSql, "\"))
    End If
    
    '检查数据库是否存在
    If sReplaceExist = False Then
        iSql = "select 1 from master..sysdatabases  where name='" & sDataBaseName & "'"
        iRe.Open iSql, iDb, adOpenKeyset, adLockReadOnly
        If iRe.EOF = False Then
            iReturn = "数据库已经存在!"
            iRe.Close
            GoTo lbExit
        End If
        iRe.Close
    End If
    
    '关闭用户进程,防止其它用户正在使用数据库,导致数据恢复失败
    iSql = "select spid from master..sysprocesses where dbid=db_id('" & sDataBaseName & "')"
    iRe.Open iSql, iDb, adOpenKeyset, adLockReadOnly
    While iRe.EOF = False
        iSql = "kill " & iRe(0)
        iDb.Execute iSql
        iRe.MoveNext
    Wend
    iRe.Close
    
    '获取数据库恢复信息
    iSql = "restore filelistonly from disk='" & sBackUpfileName & "'" & vbCrLf & _
        "with file=" & sBackupNumber
    iRe.Open iSql, iDb, adOpenKeyset, adLockReadOnly
    
    '生成数据库恢复语句
    iSql = "restore database [" & sDataBaseName & "]" & vbCrLf & _
        "from disk='" & sBackUpfileName & "'" & vbCrLf & _
        "with file=" & sBackupNumber & vbCrLf
    With iRe
        While Not .EOF
            iReturn = iRe("PhysicalName")
            iI = InStrRev(iReturn, ".")
            iReturn = IIf(iI = 0, "", Mid(iReturn, iI)) & "'"
            iSql = iSql & ",move '" & iRe("LogicalName") & _
                    "' to '" & sDataBasePath & sDataBaseName & iReturn & vbCrLf
            .MoveNext
        Wend
        .Close
    End With
    iSql = iSql & IIf(sReplaceExist, ",replace", "")
    
    iDb.Execute iSql
    iReturn = ""
    GoTo lbExit
    
lbErr:
    iReturn = Error
lbExit:
    fRestoreDatabase_a = iReturn
End Function 

Answer 3

1.备份的文件是存放在 sql server 上面
  这样不用解决备份文件的目录问题2.弹出备份对话框的问题
  因为恢复的数据文件/备份文件必须放在SQL服务器上,所以必须获得SQL服务器上的文件名及目录3.备份文件的扩展名问题
  这个你自己在程序中过滤一下就行了
4.具体的解决思路:
  a.你需要自己写一个显示磁盘选择及目录的处理过程
  b.因为要获得 SQL 服务器的信息,所以你得事先连接到sql服务器,连接的数据库可以选择master数据库
  c.获得SQL服务器上的磁盘列表,用sql语句
    exec master..xp_fixeddrives
  d.获得指定目录下的文件及文件夹,用sql语句
    exec master..xp_dirtree @path='c:\',@depth=1,@file=1 --参数:目录名,目录深度,是否显示文件
  e.对于恢复数据库,你还需要获得备份文件的信息,可以用下列SQL语句
    获得备份文件中有多少个备份及每个备份的详细信息
     RESTORE HEADERONLY from disk='x:\备份文件名'
    获得某个备份的详细信息(主要是获取逻辑文件名,以便在恢复时使用move选项将数据恢复到指定位置)
     restore filelistonly from disk='x:\备份文件名' with file=xx
  f.关于备份/恢复需要使用的backup/restore的具体用法,请参考SQL联机帮助5.具体的程序,视你使用的程序设计语言自己去写

Answer 4

to 邹健老师！
   谢谢你的指点！
   再问问：
         1.有没有现存的  显示磁盘选择及目录的处理   过程的呀？按照你的思路来做，是应该可以实现的，但没经验，所参照一下更好的解决办法。
         2.我这样的需求是否很合理？我以前也做过备份，也是自定义地选择文件进行 备份/恢复 但缺点就是限制在 sql server 服务器上，如果哪天管理员不在，那这个任务就不好完成了，对不？