例如declare @str text
set @str='1,1,2,3,4,4,3'
如何从中检索出最小且唯一值

解决方案 »

  1.   

    --参考
    拆分表:--> --> (Roy)生成測試數據
     
    if not object_id('Tab') is null
        drop table Tab
    Go
    Create table Tab([Col1] int,[COl2] nvarchar(5))
    Insert Tab
    select 1,N'a,b,c' union all
    select 2,N'd,e' union all
    select 3,N'f'
    Go--SQL2000用辅助表:
    if object_id('Tempdb..#Num') is not null
        drop table #Num
    go
    select top 100 ID=Identity(int,1,1) into #Num from syscolumns a,syscolumns b
    Select 
        a.Col1,COl2=substring(a.Col2,b.ID,charindex(',',a.Col2+',',b.ID)-b.ID) 
    from 
        Tab a,#Num b
    where
        charindex(',',','+a.Col2,b.ID)=b.ID --也可用 substring(','+a.COl2,b.ID,1)=','
    --2000不使用辅助表
    Select
        a.Col1,COl2=substring(a.Col2,b.number,charindex(',',a.Col2+',',b.number)-b.number) 
    from 
        Tab a join master..spt_values  b 
        ON B.type='p' AND B.number BETWEEN 1 AND LEN(A.col2)
    where
         substring(','+a.COl2,b.number,1)=','
    SQL2005用Xml:select 
        a.COl1,b.Col2
    from 
        (select Col1,COl2=convert(xml,'<root><v>'+replace(COl2,',','</v><v>')+'</v></root>') from Tab)a
    outer apply
        (select Col2=C.v.value('.','nvarchar(100)') from a.COl2.nodes('/root/v')C(v))b
    SQL05用CTE:;with roy as 
    (select Col1,COl2=cast(left(Col2,charindex(',',Col2+',')-1) as nvarchar(100)),Split=cast(stuff(COl2+',',1,charindex(',',Col2+','),'') as nvarchar(100)) from Tab
    union all
    select Col1,COl2=cast(left(Split,charindex(',',Split)-1) as nvarchar(100)),Split= cast(stuff(Split,1,charindex(',',Split),'') as nvarchar(100)) from Roy where split>''
    )
    select COl1,COl2 from roy order by COl1 option (MAXRECURSION 0)生成结果:
    /*
    Col1        COl2
    ----------- -----
    1           a
    1           b
    1           c
    2           d
    2           e
    3           f
    */
      

  2.   

    declare @s varchar(1000)
    select @s='1,1,2,3,4,4,9'
    select top 1 col
    from(
    select substring(@s,number,charindex(',',@s+',',number)-number)as col
    from master..spt_values
    where type='p' and number<=len(@s+'a') 
    and charindex(',',','+@s,number)=number
    )t
    group by col having count(*)=1
    order by col 
    /*
    2*/
      

  3.   

    declare @s varchar(1000)
    select @s='1,1,2,3,4,4,9'
    select top 1 substring(@s,number,charindex(',',@s+',',number)-number)as col
    from master..spt_values
    where type='p' and number<=len(@s+'a') 
    and charindex(',',','+@s,number)=number
    group by substring(@s,number,charindex(',',@s+',',number)-number)
    having count(*)=1
    order by cast(substring(@s,number,charindex(',',@s+',',number)-number)as int)
      

  4.   

    读取该字段,使用外部程序的SPLIT函数来处理,经逗号分隔的字符串,这样的效率更高,不要什么事情都从SQL语言上打主意。死脑筋