如何知道SQL SERVER是否已启动?

Question

用sqldmo,VB的示例'*************************************************************************
'**函 数 名：f_Get_ServerStatus
'**功能描述：得到SQL服务器的状态
'**输    入： sServerName   要查看状态的SQL服务器名
'**        ： sUser         登陆的用户
'**        ： sPassword     登陆密码
'**输    出：无
'**调用模块：'引用: Microsoft SQLDMO Object Library
'**作    者： 邹建
'**日    期： 2003年11月12日
Function f_Get_ServerStatus(Optional ByVal sServerName$ = "", Optional ByVal sUser$ = "", Optional ByVal sPassword$ = "")
    Dim iSQLServer As SQLDMO.SQLServer
    Dim iRe$
    
    On Error GoTo lb_Err
    Set iSQLServer = New SQLDMO.SQLServer
    With iSQLServer
        .LoginTimeout = 1
        If sUser = "" Then
            .LoginSecure = True
            .Connect sServerName
        Else
            .Connect sServerName, sUser, sPassword
        End If
        Select Case .Status
            Case SQLDMOSvc_Continuing
                iRe = "正在连接"
            Case SQLDMOSvc_Paused
                iRe = "暂停"
            Case SQLDMOSvc_Pausing
                iRe = "正在暂停"
            Case SQLDMOSvc_Running
                iRe = "运行"
            Case SQLDMOSvc_Starting
                iRe = "正在启动"
            Case SQLDMOSvc_Stopped
                iRe = "停止"
            Case SQLDMOSvc_Stopping
                iRe = "正在停止"
            Case SQLDMOSvc_Unknown
                iRe = "未知"
        End Select
        .Disconnect
    End With
    
    GoTo lb_Exit
    
lb_Err:
    MsgBox "错误:" & Error, 48
    iRe = "错误"
lb_Exit:
    If Not (iSQLServer Is Nothing) Then Set iSQLServer = Nothing
    f_Get_ServerStatus = iRe
End Function