在ORACLE自定函数中什么返回一个表的记录集

Question

1、在MSSQL中一个SELECT语句就可以，在ORACLE中什么要用到包和光标（太麻烦），
能不能不用?。
2、在ORACLE中能不能一个SELECT中嵌套一个函数。如:
select a.id,b.id from a,f_play(200) b  where a.id=b.id
3、在PHP中什么调用返回记录集的函数。

Answer 1

在ORACLE自定函数中什么返回一个表的记录集，必须用游标；在ORACLE中可以在一个SELECT中嵌套一个函数；

Answer 2

1、qiuyang_wang(小数点):TABLE型变量.什么用能否举个例子2、armu80830(此情可待)：在ORACLE中可以在一个SELECT中嵌套一个函数,能否也举个例子
   本人从MSSQL转过来，对ORACLE不熟请多多关照

Answer 3

测试过程：
1、建立测试表
CREATE TABLE student
 (
  id                         NUMBER,
  name                       VARCHAR2(30),
  sex                        VARCHAR2(10),
  address                    VARCHAR2(100),
  postcode                   VARCHAR2(10),
  birthday                   DATE,
  photo                      LONG RAW
 );
/
 
2、建立带ref cursor定义的包和包体及函数：
CREATE OR REPLACE
package pkg_test as
/* 定义ref cursor类型
   不加return类型，为弱类型，允许动态sql查询，
   否则为强类型，无法使用动态sql查询;
*/
  type myrctype is ref cursor; 
 
--函数申明
  function get(intID number) return myrctype;
end pkg_test;
/
 
CREATE OR REPLACE
package body pkg_test as
--函数体
   function get(intID number) return myrctype is
     rc myrctype;  --定义ref cursor变量
     sqlstr varchar2(500);
   begin
     if intID=0 then
        --静态测试，直接用select语句直接返回结果
        open rc for select id,name,sex,address,postcode,birthday from student;
     else
        --动态sql赋值，用:w_id来申明该变量从外部获得
        sqlstr := 'select id,name,sex,address,postcode,birthday from student where id=:w_id';
        --动态测试，用sqlstr字符串返回结果，用using关键词传递参数
        open rc for sqlstr using intid;
     end if;
 
     return rc;
   end get;
 
end pkg_test;
/
 
3、用pl/sql块进行测试：
declare
  w_rc       pkg_test.myrctype; --定义ref cursor型变量
 
  --定义临时变量，用于显示结果
  w_id       student.id%type;
  w_name     student.name%type;
  w_sex      student.sex%type;
  w_address  student.address%type;
  w_postcode student.postcode%type;
  w_birthday student.birthday%type;
 
begin
  --调用函数，获得记录集
  w_rc := pkg_test.get(1);
 
  --fetch结果并显示
 loop
 fetch w_rc into w_id,w_name,w_sex,w_address,w_postcode,w_birthday;
 exit when w_rc%notfound;
 dbms_output.put_line(w_name);
 end loop;
end;
 
4、测试结果：
通过。