怎样用代码将vb代码添加到word宏中,就是用vb代码实现word宏中的导入代码功能
解决方案 »
- 高分求SQL
- 高分请问:如何在VB里做一个类似于打印预览的控件,而且用户可以在打印预览的时候可以修改单子的长宽尺寸。
- 如何定义鼠标的右键单击事件?
- 关于安装??(高分)
- DBGrid 控件中列的数据字段能否在运行中指定(不在设计时指定,但datasource在设计时绑定到data1)?
- 帮忙分析一下<世界上最小的密码查看器(vb编的)(已经脱壳)>原理
- 求一条查询语句在(VB6.0)环境
- 在VB中能做到这一点吗?(char*)&Flag,其中Flag为整型,取其地址然后强制类型转化,我这样做的目的是能够放近东西!
- 那里有norton Antivirus 8.07.17c的注册码,谢谢大家.
- 各位,从哪里可以弄到打印机的控制代码?
- 怎样把单选控件整合到frame里面
- Access选中某个字段或者多个单元格之后可以自动求和
如果你的文档已经存在,先在程序中打开,再写入宏,再保存就行了。'1、启动word把 工具--宏--安全性--安全级 选择 低,
' 把 工具--宏--安全性--可靠发行商 勾选 信任对于“Visual Basic项目”的访问
'2、关闭word
'3、在c盘根目录下做一个叫 说明.htm 的文件
'4、本程序要先引用Microsoft Word 11.0 Object Library
'5、运行本程序,然后再用word打开c:\doc1.doc看看。
'6、windows操作系统如不在c:\windows下,请自己修改c:\windows\NOTEPAD.EXE路径和
' c:\windows\explorer.exe c:\说明.htm路径
'7、寻找windows操作系统路径,可以用API来完成,这是另外一个话题了。Private Sub Command1_Click()
Dim app As New Word.Application
Dim doc As Word.Document
Dim s1 As String, s2 As String
app.Visible = False
s1 = "Private Sub Document_Open()" & vbCr & _
" Dim iMenu As CommandBarPopup, MyMenu3 As CommandBarButton" & vbCr & _
" Dim MyMenu1 As CommandBarButton, MyMenu2 As CommandBarButton" & vbCr & _
vbCr & _
" For Each iMenu In Application.CommandBars.ActiveMenuBar.Controls" & vbCr & _
" If iMenu.Caption = ""[我的软件名称](&I)"" Then" & vbCr & _
" Exit Sub" & vbCr & _
" End If" & vbCr & _
" Next" & vbCr & _
vbCr & _
" Set iMenu = Application.CommandBars(""Menu Bar"").Controls.Add(Type:=msoControlPopup)" & vbCr & _
" iMenu.Caption = ""[我的软件名称](&I)""" & vbCr & _
vbCr & _
" Set MyMenu1 = iMenu.CommandBar.Controls.Add(Type:=msoControlButton)" & vbCr & _
" MyMenu1.Caption = ""……运行软件""" & vbCr & _
" MyMenu1.OnAction = ""a""" & vbCr & _
vbCr & _
" Set MyMenu2 = iMenu.CommandBar.Controls.Add(Type:=msoControlButton)" & vbCr & _
" MyMenu2.Caption = ""……操作帮助""" & vbCr & _
" MyMenu2.OnAction = ""b""" & vbCr & _
vbCr & _
" Set MyMenu3 = iMenu.CommandBar.Controls.Add(Type:=msoControlButton)" & vbCr & _
" MyMenu3.Caption = ""……删除按钮""" & vbCr & _
" MyMenu3.OnAction = ""c""" & vbCr & _
"End Sub"
s2 = "Private Sub a()" & vbCr & _
" '打开记事本,修改成你的程序路径" & vbCr & _
" Shell ""c:\windows\NOTEPAD.EXE"", vbNormalFocus" & vbCr & _
"End Sub" & vbCr & _
vbCr & _
"Private Sub b()" & vbCr & _
" '打开说明文件,修改成你的说明文件路径" & vbCr & _
" Shell ""c:\windows\explorer.exe c:\说明.htm"", vbNormalFocus" & vbCr & _
"End Sub" & vbCr & _
vbCr & _
"Private Sub c()" & vbCr & _
" '删除自定义按钮的方式" & vbCr & _
" Dim iMenu As CommandBarPopup" & vbCr & _
" For Each iMenu In Application.CommandBars.ActiveMenuBar.Controls" & vbCr & _
" If iMenu.Caption = ""[我的软件名称](&I)"" Then" & vbCr & _
" iMenu.Delete" & vbCr & _
" End If" & vbCr & _
" Next" & vbCr & _
"End Sub"
s1 = s1 & vbCr & s2
Set doc = Documents.Add '如果这里出现错误,请稍等一会再重新运行程序,可能是word临时文件的事
doc.VBProject.VBComponents("ThisDocument").CodeModule.AddFromString s1
doc.SaveAs FileName:="c:\doc1.doc"
doc.Close:
Set doc = Nothing
app.Quit:
Set app = Nothing
End Sub