如何利用SQL语句把Combo控件连接数据库的某个字段（新手提问）

Question

如何利用SQL语句把Combo控件连接数据库的某个字段

Answer 1

Public Sub initCmbArea()
  CmbArea.Clear
  Sql = "select A from TB"
  SqlRec.Open Sql, SQLcon
  While Not SqlRec.EOF
    CmbArea.AddItem SqlRec.Fields(0)
    SqlRec.MoveNext
  Wend
  SqlRec.Close
  Set SqlRec = Nothing
  CmbArea.ListIndex = 0
End Sub

Answer 2

Public Sub initCmbArea()
  
CmbArea.Clear
  Sql = "select A from TB"
  SqlRec.Open Sql, SQLcon
  While Not SqlRec.EOF
    CmbArea.AddItem SqlRec.Fields(0)
    SqlRec.MoveNext
  Wend
  SqlRec.Close
  Set SqlRec = Nothing
  CmbArea.ListIndex = 0
End Sub

Answer 3

Public Sub initCmbArea()
  'cmbarea为combo控件名
  CmbArea.Clear
  Sql = "select A from TB"
  dim sqlrec as new adodb.recordset
  SqlRec.Open Sql, SQLcon
  While Not SqlRec.EOF
    '向combo控件添加你要的记录
    CmbArea.AddItem SqlRec.Fields(“字段名”)
    SqlRec.MoveNext
  Wend
  SqlRec.Close
  Set SqlRec = Nothing
  CmbArea.ListIndex = 0
End Sub

Answer 4

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'子过程作用:用Book_id填充ComboBox
'参数意义:cmb:要填充的ComboBox;Stauts:填入comboBox的Book_ID的状态
'0为未借出,1为已借出
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Public Sub FillComboWithBookId(cmb As ComboBox, ByVal Status As Long)
    '定义字符串用于SQL查询
    Dim strSQL As String
    '定义ADODB连接对象用于连接到SQL数据库Library
    Dim conLIB As ADODB.Connection
    '定义ADODB命令对象用于执行SQL查询
    Dim comBookId As ADODB.Command
    '定义ADODB记录对象用于访问查询内容
    Dim rsBookId As ADODB.Recordset
    
    On Error GoTo errhandle:
    
    '连接并打开本地SQL服务器的Libray数据库
    Set conLIB = New ADODB.Connection
    Set comBookId = New ADODB.Command
    conLIB.ConnectionString = "Provider=SQLOLEDB.1;" _
                               & "Integrated Security=SSPI;" _
                               & "Persist Security Info=False;" _
                               & "Initial Catalog=Library;" _
                               & "Data Source=(local)"
    conLIB.Open
    
    '设置ADODB命令comBookId的活动连接为conLIB
    Set comBookId.ActiveConnection = conLIB
    
    
    Set rsBookId = New ADODB.Recordset
    '编写SQL语句并执行查询
    strSQL = "select book_id from books where status=" & Status & " order by book_id"
    comBookId.CommandText = strSQL
    Set rsBookId = comBookId.Execute
    
    '用数据库返回的数据填充组合框
    cmb.Clear
    Do Until rsBookId.EOF
        cmb.AddItem rsBookId!book_id
        rsBookId.MoveNext
    Loop
    
    '关闭连接
    conLIB.Close
    
    Exit Sub
    
errhandle:
    MsgBox Err.Description, vbOKOnly + vbCritical, cmb.Parent.Caption
End Sub

Answer 5

还是DataCombo最简单，直接设置数据源即可，其自动填充combobox。