怎么用sendmessage 使用LVM_SCROLLX消息，100分送上

Question

我在程序里这样用
lresult = SendMessage(lvListView.hWnd, LVM_SCROLL, 0, CInt(1))
我想让listview向下滚动一行，可是不管我最后一个参数设成150 ，1 
listview总是滚动到最下面
我的listview是report的view
我查了一些资料说，要是report的样式，最后一个应该是行数
还有，如果我要向上滚动那，用－1，也是滚动到最后一行了各位大侠，多帮帮忙了！

Answer 1

需要计算最后一个参数的值，并用byval传递该参数，下面是例子：Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
 Private Const LVM_FIRST = &H1000
 Private Const LVM_SCROLL = (LVM_FIRST + 20)Private Sub Command1_Click()
    Dim i As Long
    Dim s As String
    s = InputBox("请输入一个整数")
    i = CLng(s) * ListView1.ListItems(1).Height \ Screen.TwipsPerPixelY
    Dim l As Long
    '滚动i行
    l = SendMessage(Me.ListView1.hwnd, LVM_SCROLL, 0, ByVal i)
End SubPrivate Sub Form_Load()
    Dim i As Long
    Me.ListView1.View = lvwReport
    Me.ListView1.ColumnHeaders.Add , , "test"
    Me.ListView1.HideColumnHeaders = True
    For i = 1 To 200
        Me.ListView1.ListItems.Add , , "line" + CStr(i)
    Next
End Sub

Answer 2

强！
那能告诉我什么情况下要用byval吗
我是WINDOWS API新手
谢谢！

Answer 3

在不能并改变参数愿值时用byval传递参数

Answer 4

那能告诉我什么情况下要用byval吗
这个一句两句恐怕说不清楚，需要长期的经验积累，我的一点经验是，如果希望从api函数的参数中取回数据，一般用byref（vb中默认为byref，可省略不写），这在api函数的参数为结构体时，尤其明显。而如果要把一个值传递给api函数，则需用byval）参考：3、ByVal和ByRef
    ByVal传递的参数值，而ByRef传递的参数的地址。在这里，我们不用去区别传指针/传地址/传引用的不同，在VB里，它们根本就是一个东西的三种不同说法，即使VB的文档里也有地方在混用这些术语（但在C++里的确要区分指针和引用）
    初次接触上面的程序二SwapPtr的朋友，一定要搞清在里面的CopyMemory调用中，在什么地方要加ByVal，什么地方不加（不加ByVal就是使用VB缺省的ByRef）
    准确的理解传值和传地址（指针）的区别，是在VB里正确使用指针的基础。
    现在一个最简单的实验来看这个问题，如下面的程序三：
【程序三】：''体会ByVal和ByRef
    Sub TestCopyMemory()
        Dim k As Long
        k = 5
Note:   CopyMemory ByVal VarPtr(k), 40000, 4
        Debug.Print k
    End Sub
    上面标号Note处的语句的目的，是将k赋值为40000，等同于语句k=40000，你可以在"立即"窗口试验一下，会发现k的值的确成了40000。
    实际上上面这个语句，翻译成白话，就是从保存常数40000的临时变量处拷贝4个字节到变量k所在的内存中。
    现在我们来改变一个Note处的语句，若改成下面的语句：
Note2:   CopyMemory ByVal VarPtr(k), ByVal 40000, 4
    这句话的意思就成了，从地址40000拷贝4个字节到变量k所在的内存中。由于地址40000所在的内存我们无权访问，操作系统会给我们一个Access Violation内存越权访问错误，告诉我们"试图读取位置0x00009c40处内存时出错，该内存不能为''Read''"。
    我们再改成如下的语句看看。
Note3:   CopyMemory VarPtr(k), 40000, 4
    这句话的意思就成了，从保存常数40000的临时变量处拷贝4个字节到到保存变量k所在内存地址值的临时变量处。这不会出出内存越权访问错误，但k的值并没有变。
    我们可以把程序改改以更清楚的休现这种区别，如下面的程序四：
【程序四】：''看看我们的东西被拷贝到哪儿去了 
    Sub TestCopyMemory()
        Dim i As Long, k As Long
        k = 5
        i = VarPtr(k)
NOTE4:  CopyMemory i, 40000, 4
        Debug.Print k
        Debug.Print i
        i = VarPtr(k)
NOTE5:  CopyMemory ByVal i, 40000, 4
        Debug.Print k
    End Sub程序输出：
5
40000
40000
    由于NOTE4处使用缺省的ByVal，传递的是i的地址（也就是指向i的指针），所以常量40000拷贝到了变量i里，因此i的值成了40000，而k的值却没有变化。但是，在NOTE4前有：i=VarPtr(k)，本意是要把i本身做为一个指针来使用。这时，我们必须如NOTE5那样用ByVal来传递指针i，由于i是指向变量k的指针，所以最后常量40000被拷贝了变量k里。
    希望你已经理解了这种区别，在后面问题的讨论中，我还会再谈到它。

Answer 5

太感谢rainstormmaster了
你真太好了：）