请问 用VB做出文件列表（搜索）器的 方法

Question

就是 建一个窗口 ，窗口里有个输入框 一个按纽  一个listbox （就是列表框）然后  功能是 如果在输入框内输入 一个地址 （例如c:\windows）那么需要 在按按纽后 在列表框（listbox）里列出  这个地址下的所有文件（要列出每个文件的详细地址）包括子文件夹里的所有文件，而不显示文件夹 ，要以列表方式列出 不能用树状方式列出。 谁帮我下？谢谢了先~  如果方便加我QQ27633663

Answer 1

类似于leapftp那样的效果，不过不能显示绝对路径？关注ing...........upupup

Answer 2

帮你写了段代码，调用之前先清除ctrlList中的内容。Public Sub LoadFolderFile(ByVal strFolder As String, ctrlList As ListBox)    Dim strFullFolder As String
    strFullFolder = strFolder
    If Right(strFullFolder, 1) <> "\" Then strFullFolder = strFullFolder & "\"
    
    Dim strName As String, strFullName As String
    
    ' load all files first
    strName = Dir(strFullFolder, vbArchive + vbHidden + vbNormal + vbReadOnly + vbSystem)
    Do While Len(strName) <> 0
        strFullName = strFullFolder & strName
        ctrlList.AddItem strFullName
        strName = Dir
    Loop
    
    ' store all sub-folder name in an array then
    strName = Dir(strFullFolder & "*.*", vbDirectory)
    Dim strSubFolder() As String, i As Long
    ReDim strSubFolder(1 To 10) As String
    Dim nTotalSubFolder As Long, nArraySize As Long
    nTotalSubFolder = 0
    nArraySize = 10
    Do While Len(strName) <> 0
        If strName <> "." And strName <> ".." And _
                (GetAttr(strFullFolder & strName) And vbDirectory) = vbDirectory Then
            nTotalSubFolder = nTotalSubFolder + 1
            If nTotalSubFolder > nArraySize Then
                nArraySize = nArraySize + 10
                ReDim Preserve strSubFolder(1 To nArraySize) As String
            End If
            strSubFolder(nTotalSubFolder) = strName
        End If
        strName = Dir
    Loop
    
    ' load files in each sub-folder
    For i = 1 To nTotalSubFolder
        LoadFolderFile strFullFolder + strSubFolder(i), ctrlList
    Next
End Sub

Answer 3

1. VB 的   Dir 函数
2. API:    FindFirstFile, ...
3. Windows Shell