新手求教，请多帮忙！

Question

在vb里面 怎么样把vb界面里面的“文本框”中的内容保存到vb外面的例如.txt或者.doc的文档里面来？请求vb原代码！！

Answer 1

例顺序文件的写入，你可参照例子将text1.Text写入即可
Option Explicit
'文件_顺序文件的写入
Private Sub Form_Click()
'打开文件
    Open "A:顺序文件" For Output As #1
'写入文件
    Print #1, "Print:"
    Print #1, "A"; "B"; "C"
    Print #1, "ABC,DEF"; "GHI"; "JKL"
    Write #1, "Write:"
    Write #1, "A"; "B"; "C"
    Write #1, "ABC,DEF"; "GHI"; "JKL"
'关闭打开的文件
    Close
    CurrentX = 1000
    CurrentY = 1000
    FontSize = 20
    Print "程序已运行完毕"
    Print "  可以利用NotePad阅读文件"
    Print "阅读时文件类型要改成所有文件"
End Sub

Answer 2

另一种用方法：
'文件系统对象_文本流
Option Explicit
Private Sub Form_Click()
    Dim objA As New FileSystemObject
    Dim objB As Object
    Dim objC As File
    Dim strS As String
'利用文件系统对象的FileExists方法判断文本流对象是否存在
'如果存在则利用文件系统对象的DeleteFile方法删除
    If objA.FileExists("D:\TestStream.TXT") = True Then _
            objA.DeleteFile ("D:\TestStream.TXT")
'利用文件系统对象的OpenTextFile方法建立文本流对象
    Set objB = objA.OpenTextFile("D:\TestStream.TXT", ForAppending, True, 0)
'文本流对象的写入
    objB.Write ("星期一安排学术报告")
    objB.WriteBlankLines (3)
    objB.WriteLine ("星期二安排研究生答辩")
    objB.WriteBlankLines (2)
    objB.WriteLine ("星期三安排现场调研")
'文本流对象的关闭
    objB.Close
'利用文件系统对象的GetFile方法取得文件对象
    Set objC = objA.GetFile("D:\TestStream.TXT")
'文件对象的复制
    objC.Copy ("F:\TestStream.TXT")
'利用文件系统对象的GetFile方法取得复制后的文件对象
    Set objC = objA.GetFile("F:\TestStream.TXT")
'利用文件系统对象的OpenTextFile方法打开文本流对象
    Set objB = objA.OpenTextFile("D:\TestStream.TXT", ForReading, , 0)
'利用文本流对象的AtEndOfStream属性判断是否到文件结尾
'利用文本流对象的ReadAll方法读全部文件，并利用信息框显示
    Do While objB.AtEndOfStream <> True
        strS = objB.ReadAll
        MsgBox strS
    Loop
'关闭文本流对象
    objB.Close
'设定屏幕打印字体和打印位置
    Form1.FontName = "隶书"
    Form1.FontSize = 36
    CurrentX = 2000
    CurrentY = 1500
    Form1.Print "大功告成！"
End Sub

Answer 3

注：在Project--References-中添加引用Microsoft Scripting Runtime

Answer 4

Open App.Path & "\Config.txt" For Binary As #2
    Put #2, , text1.text
    Close #2