如何在程序里面写，在form上添加text控间，

Question

回复人：rosement()>>日期：2000-8-25 16:14:00以上的不是太全面！！！
Private Sub Form_Load()
   Form1.Controls.Add "VB.CommandButton", "cmdObj1", Frame1
   With Form1!cmdObj1
      .Visible = True
      .Width = 2000
      .Caption = "Dynamic Button"
   End With
End Sub
注意 上面的代码例子使用 ! 作为一个语法要素。您也可以使用标准集合语法如 Form1.Controls("cmdObj1") 来引用该控件。
第二个例子使用 WithEvents 关键字声明一个 CommandButton 类型的对象变量，允许您编程该控件的事件。对象变量被设置为由 Add 方法返回的引用。要试验该例，把它的代码粘贴到声明部分并且运行该工程。
Option Explicit
Private WithEvents btnObj As CommandButton
Private Sub btnObj_Click()
   MsgBox "This is a dynamically added button."
End Sub
Private Sub Form_Load()
   Set btnObj = Controls.Add("VB.CommandButton", "btnObj")
   With btnObj
      .Visible = True
      .Width = 2000
      .Caption = "Hello"
      .Top = 1000
      .Left = 1000
   End With
End Sub
第三个例子添加一个非引用控件到 Controls 集合。然而要编程这样一个控件的事件，必须声明一个 VBControlExtender 类型的对象变量，并把由这个方法返回的引用设置到该对象。然后使用 ObjectEvent 事件编程该控件的事件。
Option Explicit
Dim ctlExtender As VBControlExtender
Private Sub Form_Load()
   Set ctlExtender = Controls.Add("Project1.UserControl1", "MyControl")
   With ctlExtender 
      .Visible = True
      .Top = 1000
      .Left = 1000
   End With
End Sub
Private Sub extObj_ObjectEvent(Info As EventInfo)
   '使用 Select Case 编程该控件事件。
   Select Case Info.Name
   Case "UserName"
      '检查用户名值。
      MsgBox Info. EventParameters("UserName").Value
   '现在显示其他情况
   Case Else '未知事件
      '这里处理未知事件。
   End Select
End Sub