怎么在VB中,点击一个按钮就能重起(关机)?

Question

【函数】
ExitWindowsEx【操作系统】
Win9X:Yes
WinNT:Yes【声明】
ExitWindowsEx Lib "user32" Alias "ExitWindowsEx" (ByVal uFlags As Long, ByVal dwReserved As Long) As Long【说明】  退出windows，并用特定的选项重新启动 【返回值】  Long，非零表示成功，零表示失败。会设置GetLastError 【其它】  这个函数调用后会立刻返回，系统关闭过程是在后台进行的。注意先中止自己的应用程序，使关闭过程更显平顺。当然，您的进程必须有足够的优先权，否则也不能执行这种操作【参数表】
  uFlags ---------  Long，指定下述一个或多个标志（用OR运算符合并到一起）
  EWX_FORCE
  强迫中止没有响应的进程
  EWX_LOGOFF
  中止进程，然后注销
  EWX_SHUTDOWN
  关掉系统电源（如果可能的话，ATX电源就可以）
  EWX_REBOOT
  重新引导系统
  EWX_SHUTDOWN
  关闭系统  dwReserved -----  Long，保留，设为零

Answer 1

At NT Or 2000
'In a module
Private Const EWX_LOGOFF = 0
Private Const EWX_SHUTDOWN = 1
Private Const EWX_REBOOT = 2
Private Const EWX_FORCE = 4
Private Const TOKEN_ADJUST_PRIVILEGES = &H20
Private Const TOKEN_QUERY = &H8
Private Const SE_PRIVILEGE_ENABLED = &H2
Private Const ANYSIZE_ARRAY = 1
Private Const VER_PLATFORM_WIN32_NT = 2
Type OSVERSIONINFO
    dwOSVersionInfoSize As Long
    dwMajorVersion As Long
    dwMinorVersion As Long
    dwBuildNumber As Long
    dwPlatformId As Long
    szCSDVersion As String * 128
End Type
Type LUID
    LowPart As Long
    HighPart As Long
End Type
Type LUID_AND_ATTRIBUTES
    pLuid As LUID
    Attributes As Long
End Type
Type TOKEN_PRIVILEGES
    PrivilegeCount As Long
    Privileges(ANYSIZE_ARRAY) As LUID_AND_ATTRIBUTES
End Type
Private Declare Function GetCurrentProcess Lib "kernel32" () As Long
Private Declare Function OpenProcessToken Lib "advapi32" (ByVal ProcessHandle As Long, ByVal DesiredAccess As Long, TokenHandle As Long) As Long
Private Declare Function LookupPrivilegeValue Lib "advapi32" Alias "LookupPrivilegeValueA" (ByVal lpSystemName As String, ByVal lpName As String, lpLuid As LUID) As Long
Private Declare Function AdjustTokenPrivileges Lib "advapi32" (ByVal TokenHandle As Long, ByVal DisableAllPrivileges As Long, NewState As TOKEN_PRIVILEGES, ByVal BufferLength As Long, PreviousState As TOKEN_PRIVILEGES, ReturnLength As Long) As Long
Private Declare Function ExitWindowsEx Lib "user32" (ByVal uFlags As Long, ByVal dwReserved As Long) As Long
Private Declare Function GetVersionEx Lib "kernel32" Alias "GetVersionExA" (ByRef lpVersionInformation As OSVERSIONINFO) As Long
'Detect if the program is running under Windows NT
Public Function IsWinNT() As Boolean
    Dim myOS As OSVERSIONINFO
    myOS.dwOSVersionInfoSize = Len(myOS)
    GetVersionEx myOS
    IsWinNT = (myOS.dwPlatformId = VER_PLATFORM_WIN32_NT)
End Function
'set the shut down privilege for the current application
Private Sub EnableShutDown()
    Dim hProc As Long
    Dim hToken As Long
    Dim mLUID As LUID
    Dim mPriv As TOKEN_PRIVILEGES
    Dim mNewPriv As TOKEN_PRIVILEGES
    hProc = GetCurrentProcess()
    OpenProcessToken hProc, TOKEN_ADJUST_PRIVILEGES + TOKEN_QUERY, hToken
    LookupPrivilegeValue "", "SeShutdownPrivilege", mLUID
    mPriv.PrivilegeCount = 1
    mPriv.Privileges(0).Attributes = SE_PRIVILEGE_ENABLED
    mPriv.Privileges(0).pLuid = mLUID
    ' enable shutdown privilege for the current application
    AdjustTokenPrivileges hToken, False, mPriv, 4 + (12 * mPriv.PrivilegeCount), mNewPriv, 4 + (12 * mNewPriv.PrivilegeCount)
End Sub
' Shut Down NT
Public Sub ShutDownNT(Force As Boolean)
    Dim ret As Long
    Dim Flags As Long
    Flags = EWX_SHUTDOWN
    If Force Then Flags = Flags + EWX_FORCE
    If IsWinNT Then EnableShutDown
    ExitWindowsEx Flags, 0
End Sub
'Restart NT
Public Sub RebootNT(Force As Boolean)
    Dim ret As Long
    Dim Flags As Long
    Flags = EWX_REBOOT
    If Force Then Flags = Flags + EWX_FORCE
    If IsWinNT Then EnableShutDown
    ExitWindowsEx Flags, 0
End Sub
'Log off the current user
Public Sub LogOffNT(Force As Boolean)
    Dim ret As Long
    Dim Flags As Long
    Flags = EWX_LOGOFF
    If Force Then Flags = Flags + EWX_FORCE
    ExitWindowsEx Flags, 0
End Sub
'In a form
'This project needs a form with three command buttons
Private Sub Command1_Click()
    LogOffNT True
End Sub
Private Sub Command2_Click()
    RebootNT True
End Sub
Private Sub Command3_Click()
    ShutDownNT True
End Sub
Private Sub Form_Load()
    Command1.Caption = "Log Off NT"
    Command2.Caption = "Reboot NT"
    Command3.Caption = "Shutdown NT"
End Sub

Answer 2

如何讓 Windows(95 及 NT) 重新開機 
 
  
  
          
 Windows 95 重新開機十分簡單，只要呼叫 ExitWindowsEx API 函數就可以了， 例如： API 宣告式: Private Declare Function ExitWindowsEx Lib "user32" (ByVal uFlags As Long , _
                 ByVal dwReserved As Long) As Long Private Enum HowExitConst
               EWX_LOGOFF = 0 ' 登出
               EWX_REBOOT = 2 ' 重開機
               EWX_SHUTDOWN = 1 ' 關機
               EWX_FORCE = 4 ' 強制關機
 End Enum 呼叫敘述：     Call ExitWindowsEx(how, 0)
     ' how 等於 EWX_LOGOFF 、 EWX_REBOOT 、EWX_SHUTDOWN 、 或EWX_FORCE但是這個方法並不能對 NT 關機或重新開機， 原因是 NT 比較著重安全性(Security)，
而為了讓 NT 關機或重新開機， 則必須在呼叫 ExitWindowsEx 之前， 呼叫
AdjustToken 副程式就對了。AdjustToken 副程式的細節如下：1. API 的宣告：  Enum HowExitConst
               EWX_FORCE = 4 ' 強制關機
               EWX_LOGOFF = 0 ' 登出
               EWX_REBOOT = 2 ' 重開機
               EWX_SHUTDOWN = 1 ' 關機
  End Enum  Const TOKEN_ADJUST_PRIVILEGES = &H20
  Const TOKEN_QUERY = &H8
  Const SE_PRIVILEGE_ENABLED = &H2
  Const ANYSIZE_ARRAY = 1
  Private Type LUID
               lowpart As Long
               highpart As Long
  End Type Private Type LUID_AND_ATTRIBUTES
        pLuid As LUID
        Attributes As Long
 End Type Private Type TOKEN_PRIVILEGES
              PrivilegeCount As Long
              Privileges(ANYSIZE_ARRAY) As LUID_AND_ATTRIBUTES
 End Type Private Declare Function ExitWindowsEx Lib "user32" (ByVal uFlags As Long, _
         ByVal dwReserved As Long) As Long
 Private Declare Function GetCurrentProcess Lib "kernel32" () As Long
 Private Declare Function LookupPrivilegeValue Lib"advapi32.dll" Alias _
         "LookupPrivilegeValueA" (ByVal lpSystemName As String, _
         ByVal lpName As String, lpLuid As LUID) As Long
 Private Declare Function AdjustTokenPrivileges Lib "advapi32.dll" _
         (ByVal TokenHandle As Long, ByVal DisableAllPrivileges As Long, _
         NewState As TOKEN_PRIVILEGES, ByVal BufferLength As Long, _
         PreviousState As TOKEN_PRIVILEGES, ReturnLength As Long) As Long
 Private Declare Function OpenProcessToken Lib "advapi32.dll" _
         (ByVal ProcessHandle As Long, ByVal DesiredAccess As Long, _
          TokenHandle As Long) As Long2. AdjustToken 副程式：Private Sub AdjustToken() Dim hdlProcessHandle As Long
 Dim hdlTokenHandle As Long
 Dim tmpLuid As LUID
 Dim tkp As TOKEN_PRIVILEGES
 Dim tkpNewButIgnored As TOKEN_PRIVILEGES
 Dim lBufferNeeded As Long
 　
 hdlProcessHandle = GetCurrentProcess()
 OpenProcessToken hdlProcessHandle,(TOKEN_ADJUST_PRIVILEGES Or TOKEN_QUERY), _
        hdlTokenHandle 'Get the LUID for shutdown privilege.
 LookupPrivilegeValue "","SeShutdownPrivilege", tmpLuid
 tkp.PrivilegeCount = 1 ' One privilege to set
 tkp.Privileges(0).pLuid = tmpLuid
 tkp.Privileges(0).Attributes = SE_PRIVILEGE_ENABLED 'Enable the shutdown privilege in the access token of this process.
 AdjustTokenPrivileges hdlTokenHandle, False, tkp, Len(tkpNewButIgnored), _
                       tkpNewButIgnored, lBufferNeeded
End Sub3. 呼叫的範例： AdjustToken
 Call ExitWindowsEx(how, 0)
 'how 等於 EWX_LOGOFF 、 EWX_REBOOT 、 EWX_SHUTDOWN、 或EWX_FORCE在 Windows 95 底下呼叫了 AdjustToken 也沒關係，因為 Windows 95 並不會
理會安全性的設定。
在95/98下其實還可以呼叫
rundll user.exe,exitwindows來離開
 
 

Answer 3

At 98'In general section
Const EWX_LOGOFF = 0
Const EWX_SHUTDOWN = 1
Const EWX_REBOOT = 2
Const EWX_FORCE = 4
Private Declare Function ExitWindowsEx Lib "user32" (ByVal uFlags As Long, ByVal dwReserved As Long) As Long
Private Sub Form_Load()
    msg = MsgBox("This program is going to reboot your computer. Press OK to continue or Cancel to stop.", vbCritical + vbOKCancel + 256, App.Title)
    If msg = vbCancel Then End
    'reboot the computer
    ret& = ExitWindowsEx(EWX_FORCE Or EWX_REBOOT, 0)
End Sub其实上面的代码只是参数不同而已，看API的详细解释，您就该明白了

Answer 4

在95/98下其實還可以呼叫
shell "rundll user.exe,exitwindows"
 

Answer 5

在nt/2k下其實還可以呼叫
shell "rundll32 user.exe,exitwindows"

Answer 6

'In general section
Const EWX_LOGOFF = 0
Const EWX_SHUTDOWN = 1
Const EWX_REBOOT = 2
Const EWX_FORCE = 4
Private Declare Function ExitWindowsEx Lib "user32" (ByVal uFlags As Long, ByVal dwReserved As Long) As Long
Private Sub Form_Load()
    'KPD-Team 1998
    'URL: http://www.allapi.net/
    'E-Mail: [email protected]
    msg = MsgBox("This program is going to reboot your computer. Press OK to continue or Cancel to stop.", vbCritical + vbOKCancel + 256, App.Title)
    If msg = vbCancel Then End
    'reboot the computer
    ret& = ExitWindowsEx(EWX_FORCE Or EWX_REBOOT, 0)
End Sub
ExitWindowsEx VB声明 
Declare Function ExitWindowsEx Lib "user32" Alias "ExitWindowsEx" (ByVal uFlags As Long, ByVal dwReserved As Long) As Long 
说明 
退出windows，并用特定的选项重新启动 
返回值 
Long，非零表示成功，零表示失败。会设置GetLastError 
参数表 
参数 类型及说明 
uFlags Long，指定下述一个或多个标志（用OR运算符合并到一起） 
EWX_FORCE 强迫中止没有响应的进程 
EWX_LOGOFF 中止进程，然后注销 
EWX_SHUTDOWN 关掉系统电源（如果可能的话，ATX电源就可以） 
EWX_REBOOT 重新引导系统 
EWX_SHUTDOWN 关闭系统 
dwReserved Long，保留，设为零 
注解 
这个函数调用后会立刻返回，系统关闭过程是在后台进行的。注意先中止自己的应用程序，使关闭过程更显平顺。当然，您的进程必须有足够的优先权，否则也不能执行这种操作 Top
 

Answer 7

在95/98下其實還可以呼叫
重起用什么呼叫?
还有shell加在什么地方?