1.如何列举局域网网络打印机共享名称，2.指定IP的打印机的共享名称，3.直接向多台打印机发送控制符--？

Question

关于网络打印：
1.如何列举局域网网络打印机共享名称？
2.如何列举指定IP的电脑上的打印机的共享名称？
3.如何直接向打印机发送控制符（如：ESC $21 $12）？
4.如何直接利用打印机内部字库打印，这样比图形打印要快?
5.如何同时（给定时间内）向多台打印机发送打印内容?问题1，2的目的:让用户方便设定打印机；
问题3，4的目的:用于连续不定长度页面的打印，如POS机打印；
问题5的目的:用于多台打印机同时分别输出不同内容,用于餐饮系统厨房打印；问题1，2解决后，问题3，4就可以解决:
procedrue pPrintDoc(AStrs:TStrings);
var ATxtF:Textfile;
    ATxtFileName:String;
    AIPAdr,APrinterName:String;
    AIx,AIc:Integer;
begin
  AIPAdr:='127.0.0.1';
  APrinterName:='LQ100';//共享名称，而不是属性名称
  ATxtFileName:='\\'+IPAdr+'\'+APrinterName;
  AssignFile(ATxtF,ATxtFileName);
  try
    ReWrite(ATxtF);
    AIc:=AStrs.Count;
    for AIx:=0 to AIc-1 do
    begin
      WriteLn(ATxtF,AStrs[AIx]);
    end;
  finally
    CloseFile(ATxtF);
  end;
end;请各位高手指教。

Answer 1

BOOL SetPrinter(    HANDLE hPrinter, // handle of printer object 
    DWORD Level, // structure level 
    LPBYTE pPrinter, // address of array containing printer data  
    DWORD Command  // printer-state command 
   ); 其实我也不清楚怎样用

Answer 2

现在手头没有局域网，没做测试在程序中获取网络资源信息　　充分利用局域网中的共享资源,无疑将减少用户的硬件和软件投资。在我们的程序中,常常会需要列举局域网络中的共享资源,如在ＭＩＤＡＳ多层应用程序中可能要选择上层应用程序所在的服务器的名称、在打印模块中选择可用的网络打印机、在应用程序中选择其它机器上的共享文件等。
以一个ＭＩＤＡＳ三层数据库应用程序为例子,我们可以用ＤＥＬＰＨＩ制作一个客户端应用程序和一个中间层业务处理程序,由中间层业务处理程序向数据库存取数据,再将结果反馈到客户端。当客户端应用程序与中间层程序和数据库服务程序不在一台机器上时,需要指定中间层程序和数据库服务程序所在的服务器的名称。
　　在ＤＥＬＰＨＩ程序中,我们可以通过ＷＩＮ　ＡＰＩ来列举局域网络中的服务器名称、用户计算机名称、用户共享目录和文件、共享打印机等资源,这些ＡＰＩ由文件ＭＰＲ．ＤＬＬ提供。
下面以ＷＩＮ９Ｘ的对等网络为例子,列举“网络邻居”中的工作组名称、用户计算机名称、共享目录和文件、共享打印机等资源。
　　一、列举“网络邻居”中的工作组名称
　　在“网络邻居”中,打开“整个网络”,可以看到网络中的所有工作组的名称。在ＤＥＬＰＨＩ程序中,可以用ＡＰＩ函数WNetOpenEnum和WNetEnumResource来列举“网络邻居”中的工作组名称。
下面是两个ＡＰＩ函数的简介,具体请参见ＤＥＬＰＨＩ帮助文件。
//WNetOpenEnum用于获取一个网络资源句柄,作为WNetEnumResource列举网络资源的依据,其函数原型如下:
function WNetOpenEnum(
dwScope,//网络范围,RESOURCE_CONNECTED(已连接机器),RESOURCE_GLOBALNET(所有机器),
　　　　RESOURCE_REMEMBERED(已记忆的机器)
dwType,//资源类型,RESOURCETYPE_ANY(所有资源),RESOURCETYPE_DISK(文件资源),
　　　 RESOURCETYPE_PRINT(打印资源)
dwUsage//资源用途,0(所有资源),RESOURCEUSAGE_CONNECTABLE(所有可连接资源),
　　　 RESOURCEUSAGE_CONTAINER(所有container资源)仅在dwScope为RESOURCE_GLOBALNET是有效
: DWORD;
lpNetResource: PNetResource;//NetResource类型指针,其内存表示网络资源的层次,为NIL时表示最上层,仅在dwScope为RESOURCE_GLOBALNET时有效,其它情况时应为NIL
var lphEnum: THandle//返回网络资源句柄,是WNetEnumResource进一步列举网络资源的依据): DWORD; stdcall;返回值NO_ERROR表示执行成功,否则应用GetLastError获取错误信息
//WNetEnumResource用于列出当前网络中可用的资源,包括文件资源和打印资源,其函数原型如下:
function WNetEnumResource(
hEnum: THandle;//WNetEnumResource进一步列举网络资源的依据,通常由WNetOpenEnum取得var lpcCount: DWORD;//要取得资源的数目,$FFFFFFFF表示列出所有资源,返回值为实际资源数目lpBuffer: Pointer;//接收结果的缓冲区的指针,一般是NetResource类型的数组
var lpBufferSize: DWORD//接收结果的缓冲区大小(Byte)
): DWORD; stdcall;
返回值为NO_ERROR(执行成功)或ERROR_NO_MORE_ITEMS(资源列举完毕),否则应用GetLastError获取
错误信息。
　　要列举网络中的工作组信息,首先要获取网络中的网络类型,再获取每一种类型网络中包含的工作组的名称。
　　1、获取网络类型信息
　　　　局域网中可以是由多种类型的网络组成,如由Microsoft、Novell等类型的网络组成。用ＡＰＩ　　函数WNetOpenEnum和WNetEnumResource可以获取网络类型信息。
　　(1)用WNetOpenEnum函数返回一个句柄,作为WNetEnumResource列举网络资源的依据。我们的目标是列举“整个网络”的工作组名称,因而网络范围为RESOURCE_GLOBALNET(所有机器)、资源类型为RESOURCETYPE_DISK(文件资源)、资源用途为RESOURCEUSAGE_CONTAINER(所有container资源)、
　　　网络层次为最高层(NIL),这样可以得到一个句柄,以便进一步列举网络资源。具体的程序段如下:
{ Res : DWORD; lphEnum : THandle; }
Res := WNetOpenEnum( RESOURCE_GLOBALNET, RESOURCETYPE_DISK,
RESOURCEUSAGE_CONTAINER, Nil,lphEnum);
If Res <> NO_ERROR Then exit;//执行失败
　　(２)用ＡＰＩ函数WNetEnumResource可以获取网络类型信息,此时要用到上面获取的句柄lphEnum,
　　　可以获取一个NetResource类型的数组,每个NetResource元素即为一种网络类型信息。
　　　具体的请参见以下程序段及注释信息。
type
TNetResourceArray = ^TNetResource;//网络类型的数组
Var
NetResource : TNetResource;
Buf : Pointer;
Count,BufSize,Res : DWORD;
lphEnum : THandle;
p : TNetResourceArray;
i,j : SmallInt;
NetworkTypeList : TList;
begin
......
Count := $FFFFFFFF;//不限资源数目
BufSize := 8192;//缓冲区大小设置为8K
GetMem(Buf, BufSize);//申请内存,用于获取工作组信息
Res := WNetEnumResource(lphEnum, Count, Pointer(Buf), BufSize);//获取网络类型信息
If ( Res = ERROR_NO_MORE_ITEMS )//资源列举完毕
or (Res <> NO_ERROR )//执行失败
Then Exit;
P := TNetResourceArray(Buf);
For I := 0 To Count - 1 Do//记录各个网络类型的信息
Begin
NetworkTypeList.Add(p);
Inc(P);
End;
......
end;
　　２、获取工作组信息
　　　　在获取网络类型信息后,可以根据此信息获取此类型网络中的服务器(工作组)信息。
　　　　在WNetOpenEnum函数中,将参数lpNetResource指定为一种网络类型信息,可以获取一个句柄,在WNetEnumResource中利用这个句柄,可以获取一个NetResource类型的数组,每个NetResource元素的lpRemoteName部分即为一个工作组名称(如MyWorkGroup”)。
　　　　具体的请参见以下程序段及注释信息。
//列出一个网络类型中的所有工作组名称
NetResource := TNetResource(NetworkTypeList.Items[J]^);//网络类型信息
//获取某个网络类型的文件资源的句柄,NetResource为网络类型信息,lphEnum为返回句柄
Res := WNetOpenEnum(RESOURCE_GLOBALNET, RESOURCETYPE_DISK,
RESOURCEUSAGE_CONTAINER, @NetResource,lphEnum);
If Res <> NO_ERROR Then break;//执行失败
While true Do//列举一个网络类型的所有工作组的信息
Begin
Count := $FFFFFFFF;//不限资源数目
BufSize := 8192;//缓冲区大小设置为8K
GetMem(Buf, BufSize);//申请内存,用于获取工作组信息
//获取一个网络类型的文件资源信息,
Res := WNetEnumResource(lphEnum, Count, Pointer(Buf), BufSize);
If ( Res = ERROR_NO_MORE_ITEMS ) //资源列举完毕
or (Res <> NO_ERROR) //执行失败
then break;
P := TNetResourceArray(Buf);
For I := 0 To Count - 1 Do//列举各个工作组的信息
Begin
List.Add( StrPAS( P^.lpRemoteName ));//取得一个工作组的名称
Inc(P);
End;
End;
　　３、获取工作组信息的完全源代码
//列举出整个网络中的工作组名称,返回值为TRUE表示执行成功,
//参数List中返回服务器(工作组)的名称
Function GetServerList( var List : TStringList ) : Boolean;
Var
NetResource : TNetResource;
Buf : Pointer;
Count,BufSize,Res : DWORD;
lphEnum : THandle;
p : TNetResourceArray;
i,j : SmallInt;
NetworkTypeList : TList;
Begin
Result := False;
NetworkTypeList := TList.Create;
List.Clear;
//获取整个网络中的文件资源的句柄,lphEnum为返回名柄
Res := WNetOpenEnum( RESOURCE_GLOBALNET, RESOURCETYPE_DISK,
RESOURCEUSAGE_CONTAINER, Nil,lphEnum);
If Res <> NO_ERROR Then exit;//Raise Exception(Res);//执行失败
//获取整个网络中的网络类型信息
Count := $FFFFFFFF;//不限资源数目
BufSize := 8192;//缓冲区大小设置为8K
GetMem(Buf, BufSize);//申请内存,用于获取工作组信息
Res := WNetEnumResource(lphEnum, Count, Pointer(Buf), BufSize);
If ( Res = ERROR_NO_MORE_ITEMS )//资源列举完毕
or (Res <> NO_ERROR )//执行失败
Then Exit;
P := TNetResourceArray(Buf);
For I := 0 To Count - 1 Do//记录各个网络类型的信息
Begin
NetworkTypeList.Add(p);
Inc(P);
End;
//WNetCloseEnum关闭一个列举句柄
Res := WNetCloseEnum(lphEnum);//关闭一次列举
If Res <> NO_ERROR Then exit;
For J := 0 To NetworkTypeList.Count-1 Do //列出各个网络类型中的所有工作组名称
Begin//列出一个网络类型中的所有工作组名称
NetResource := TNetResource(NetworkTypeList.Items[J]^);//网络类型信息
//获取某个网络类型的文件资源的句柄,NetResource为网络类型信息,lphEnum为返回名柄
Res := WNetOpenEnum(RESOURCE_GLOBALNET, RESOURCETYPE_DISK,
RESOURCEUSAGE_CONTAINER, @NetResource,lphEnum);
If Res <> NO_ERROR Then break;//执行失败
While true Do//列举一个网络类型的所有工作组的信息
Begin
Count := $FFFFFFFF;//不限资源数目
BufSize := 8192;//缓冲区大小设置为8K
GetMem(Buf, BufSize);//申请内存,用于获取工作组信息
//获取一个网络类型的文件资源信息,
Res := WNetEnumResource(lphEnum, Count, Pointer(Buf), BufSize);
If ( Res = ERROR_NO_MORE_ITEMS ) //资源列举完毕
or (Res <> NO_ERROR) //执行失败
then break;
P := TNetResourceArray(Buf);
For I := 0 To Count - 1 Do//列举各个工作组的信息
Begin
List.Add( StrPAS( P^.lpRemoteName ));//取得一个工作组的名称
Inc(P);
End;
End;
Res := WNetCloseEnum(lphEnum);//关闭一次列举
If Res <> NO_ERROR Then break;//执行失败
End;
Result := True;
FreeMem(Buf);
NetworkTypeList.Destroy;
End;

Answer 3

二、列举一个工作组中的计算机名称
　　　　在WNetOpenEnum函数中,将参数lpNetResource中的lpRemoteName部分指定为一个工作组的名称(如“MyWorkGroup”),可以获取一个句柄,在WNetEnumResource中利用这个句柄,可以获取一个NetResource类型的数组,每个NetResource元素的lpRemoteName部分即为一个计算机名称(如“\\wangfajun”)。
　　　　具体的请参见以下程序段及注释信息。
NetResource.lpRemoteName := @GroupName[1];//指定工作组名称
NetResource.dwDisplayType := RESOURCEDISPLAYTYPE_SERVER;//显示类型为服务器(工作组)
NetResource.dwUsage := RESOURCEUSAGE_CONTAINER;
NetResource.dwScope := RESOURCETYPE_DISK;//列举文件资源信息
//获取指定工作组的网络资源句柄
Res := WNetOpenEnum( RESOURCE_GLOBALNET, RESOURCETYPE_DISK,
RESOURCEUSAGE_CONTAINER, @NetResource,lphEnum);
　　获取计算机名称的完全程序源代码如下:
//列举出指定工作组GroupName中的计算机名称,返回值为TRUE表示执行成功,
//参数List中返回计算机名称
Function GetUsers( GroupName : string; var List : TStringList ) : Boolean;
Var
NetResource : TNetResource;
Buf : Pointer;
Count,BufSize,Res : DWord;
Ind : Integer;
lphEnum : THandle;
Temp : TNetResourceArray;
Begin
Result := False;
List.Clear;
FillChar(NetResource, SizeOf(NetResource), 0);//初始化网络层次信息
NetResource.lpRemoteName := @GroupName[1];//指定工作组名称
NetResource.dwDisplayType := RESOURCEDISPLAYTYPE_SERVER;//类型为服务器(工作组)
NetResource.dwUsage := RESOURCEUSAGE_CONTAINER;
NetResource.dwScope := RESOURCETYPE_DISK;//列举文件资源信息
//获取指定工作组的网络资源句柄
Res := WNetOpenEnum( RESOURCE_GLOBALNET, RESOURCETYPE_DISK,
RESOURCEUSAGE_CONTAINER, @NetResource,lphEnum);
If Res <> NO_ERROR Then Exit; //执行失败
While True Do//列举指定工作组的网络资源
Begin
Count := $FFFFFFFF;//不限资源数目
BufSize := 8192;//缓冲区大小设置为8K
GetMem(Buf, BufSize);//申请内存,用于获取工作组信息
//获取计算机名称
Res := WNetEnumResource(lphEnum, Count, Pointer(Buf), BufSize);
If Res = ERROR_NO_MORE_ITEMS Then break;//资源列举完毕
If (Res <> NO_ERROR) then Exit;//执行失败
Temp := TNetResourceArray(Buf);
For Ind := 0 to Count - 1 do//列举工作组的计算机名称
Begin
//获取工作组的计算机名称,+2表示删除"\\",如\\wangfajun=>wangfajun
List.Add(Temp^.lpRemoteName + 2);
Inc(Temp);
End;
End;
Res := WNetCloseEnum(lphEnum);//关闭一次列举
If Res <> NO_ERROR Then exit;//执行失败
Result := True;
FreeMem(Buf);
End;
　　三、列举一个计算机中的共享资源
　　　　在WNetOpenEnum函数中,将参数lpNetResource中的lpRemoteName部分指定为一个计算机的名称(如“\\wangfajun”),可以获取一个句柄,在WNetEnumResource中利用这个句柄,可以获取一个NetResource类型的数组,每个NetResource元素的lpRemoteName部分即为计算机中的共享资源名称(可以是共享目录和文件名称、共享打印机名称等,如“\\wangfajun\共享文件”)。
　　　　具体的请参见以下程序段及注释信息。
NetResource.lpRemoteName := @UserName[1];//指定计算机名称
//获取指定计算机的网络资源句柄
Res := WNetOpenEnum( RESOURCE_GLOBALNET, RESOURCETYPE_ANY,
RESOURCEUSAGE_CONNECTABLE, @NetResource,lphEnum);
　　获取计算机名称的完全程序源代码如下:
//列举出指定计算机UserName中的共享资源名称,返回值为TRUE表示执行成功,
//参数List中返回共享资源名称
Function GetUserResource( UserName : string ; var List : TStringList ) : Boolean;
Var
NetResource : TNetResource;
Buf : Pointer;
Count,BufSize,Res : DWord;
Ind : Integer;
lphEnum : THandle;
Temp : TNetResourceArray;
Begin
Result := False;
List.Clear;
FillChar(NetResource, SizeOf(NetResource), 0);//初始化网络层次信息
NetResource.lpRemoteName := @UserName[1];//指定计算机名称
//获取指定计算机的网络资源句柄
Res := WNetOpenEnum( RESOURCE_GLOBALNET, RESOURCETYPE_ANY,
RESOURCEUSAGE_CONNECTABLE, @NetResource,lphEnum);
If Res <> NO_ERROR Then exit;//执行失败
While True Do//列举指定工作组的网络资源
Begin
Count := $FFFFFFFF;//不限资源数目
BufSize := 8192;//缓冲区大小设置为8K
GetMem(Buf, BufSize);//申请内存,用于获取工作组信息
//获取指定计算机的网络资源名称
Res := WNetEnumResource(lphEnum, Count, Pointer(Buf), BufSize);
If Res = ERROR_NO_MORE_ITEMS Then break;//资源列举完毕
If (Res <> NO_ERROR) then Exit;//执行失败
Temp := TNetResourceArray(Buf);
For Ind := 0 to Count - 1 do
Begin
//获取指定计算机中的共享资源名称,+2表示删除"\\",
//如\\wangfajun=>wangfajun
List.Add(Temp^.lpRemoteName + 2);
Inc(Temp);
End;
End;
Res := WNetCloseEnum(lphEnum);//关闭一次列举
If Res <> NO_ERROR Then exit;//执行失败
Result := True;
FreeMem(Buf);
End;
　　以上程序在PWIN98+DELPHI3.0下调试通过。