寻求计算一个字符串表达式值的算法？

Question

我有一个字符串表达式，如：
s1="10+20*(3-5)/6+(4+(3+5)*6)"
我希望得到如下的计算式：
d1=10+20*(3-5)/6+(4+(3+5)*6)
寻求完成这种功能的算法，解决了可再加分。

Answer 1

Pascal不支持这样的转化，你可以用别的语言写一个dll，然后在Delphi中调用它，传入s1,然后让dll返回运算结果。————————————————————————————————————
宠辱不惊，看庭前花开花落，去留无意；毁誉由人，望天上云卷云舒，聚散任风。
————————————————————————————————————

Answer 2

在Delphi中安装Microsoft Script Control 1.0的ActiveX控件，添加到窗体上，用以下的代码就行了：
ScriptControl1.Language:='vbscript';
Edit1.Text:=ScriptControl1.Eval('10+20*(3-5)/6+(4+(3+5)*6)');

Answer 3

直接转换有点困难，如果你只是简单的要求表达式的值的话，用'select '+sl+'  as AA'. 可得到结果

Answer 4

标题:计算表达式
说明:加、减、乘、除及括号;请大家多多测试
设计:Zswang
日期:2002-01-26
支持:[email protected] 
///////Begin Source
uses
  Math;
 
procedure Bracket(mText: string; var nLStr, nCStr, nRStr: string);
var
  L, R: Integer;
  I: Integer;
  B: Boolean;
begin
  nLStr := '';
  nCStr := '';
  nRStr := '';
  B := True;
  L := 0;
  R := 0;
  for I := 1 to Length(mText) do
    if B then begin
      if mText[I] = '(' then
        Inc(L)
      else if mText[I] = ')' then
        Inc(R);
      if L = 0 then
        nLStr := nLStr + mText[I]
      else if L > R then
        nCStr := nCStr + mText[I]
      else B := False;
    end else nRStr := nRStr + mText[I];
  Delete(nCStr, 1, 1);
end; { Bracket }
 
function Calc(mText: string): string;
var
  vText: string;
 
  function fCalc(mText: string): string;
  var
    vLStr, vCStr, vRStr: string;
    I, J, K, L: Integer;
  begin
    L := Length(mText);
    if Pos('(', mText) > 0 then begin
      Bracket(mText, vLStr, vCStr, vRStr);
      Result := fCalc(vLStr + fCalc(vCStr) + vRStr);
    end else if (Pos('+', mText) > 0) or (Pos('-', mText) > 0) then begin
      I := Pos('+', mText);
      J := Pos('-', mText);
      if I = 0 then I := L;
      if J = 0 then J := L;
      K := Min(I, J);
      vLStr := Copy(mText, 1, Pred(K));
      vRStr := Copy(mText, Succ(K), L);
      if vLStr = '' then vLStr := '0';
      if vRStr = '' then vRStr := '0';
      if I = K then
        Result := FloatToStr(StrToFloat(fCalc(vLStr)) + StrToFloat(fCalc(vRStr)))
      else Result := FloatToStr(StrToFloat(fCalc(vLStr)) - StrToFloat(fCalc(vRStr)))
    end else if (Pos('*', mText) > 0) or (Pos('/', mText) > 0) then begin
      I := Pos('*', mText);
      J := Pos('/', mText);
      if I = 0 then I := L;
      if J = 0 then J := L;
      K := Min(I, J);
      vLStr := Copy(mText, 1, Pred(K));
      vRStr := Copy(mText, Succ(K), L);
      if vLStr = '' then vLStr := '0';
      if vRStr = '' then vRStr := '0';
      if I = K then
        Result := FloatToStr(StrToFloat(fCalc(vLStr)) * StrToFloat(fCalc(vRStr)))
      else Result := FloatToStr(StrToFloat(fCalc(vLStr)) / StrToFloat(fCalc(vRStr)))
    end else if Pos('_', mText) = 1 then
      Result := FloatToStr(-StrToFloat(fCalc(Copy(mText, 2, L))))
    else Result := FloatToStr(StrToFloat(mText));
  end;
var
  I, L: Integer;
begin
  vText := '';
  L := Length(mText);
  for I := 1 to L do
    if (mText[I] = '-') and (I < L) and (not (mText[Succ(I)] in ['+', '-', '(', ')'])) then
      if (I = 1) or ((I > 1) and (mText[Pred(I)] in ['*', '/'])) then
        vText := vText + '_'
      else if ((I > 1) and (mText[Pred(I)] in ['+', '-'])) or
        ((I < L) and (not (mText[Succ(I)] in ['+', '-', '(', ')']))) then
        vText := vText + '+_'
      else vText := vText + mText[I]
    else vText := vText + mText[I];
  Result := fCalc(vText);
end; { Calc }
///////End Source
 
///////Begin Demo
procedure TForm1.Button1Click(Sender: TObject);
begin
  Edit1.Text := Calc(Edit2.Text);
end;
///////End Demo