case 语句

Question

请教各位高手，case 语句是不是只能对序数据类型的数据进行判断啊？下面的判断能否实现？
case str of
   'a':
       statement1;
   'b':
       statement2;
end;
其中str是string类型。

Answer 1

要转换一下。CASE中不能用STRING。

Answer 2

我的本意是这样的：
在一个treeView中有n个结点，当我双击某一个结点时，想根据结点的标题的不同来执行不同的操作，如果不能用case，那么if的嵌套也就太多了，那有什么别的办法呀？

Answer 3

不能用case string的尽量换用integer形

Answer 4

你在建树的时候可以设定好各节点的 SelectedIndex来作为case的条件

Answer 5

在 case 语句中使用字符串 --- by 熊恒(beta)我今天要介绍的是一个比较另类的方法。大家都知道，case 语句只能对顺序类型
（ordinal type）管用，那么我们先看一下顺序类型到底有那些呢：1)整型；2)字
符型；3)枚举型。
于是也就演化出三种在 case 语句里面使用字符串的方法（耐心看下去哦，最后一
种方法才是今天的重点:-p）：假如我们的具体应用如下（理想的，但是错误的写法）：  str := 'Chongqing';
  case str of // 编译器将在这一行制止你 :-(
    'Beijing':    ShowMessage('First');
    'Tianjing':    ShowMessage('Second');
    'Shanghai':    ShowMessage('Third');
    'Chongqing':  ShowMessage('Forth');
    else          ShowMessage('Other');
  end;法一：字符串转为整型
  这应该是比较通行的方法了，主要是利用 TStringList。先把备选的字符串挨个 
Add 进去，然后调用其 IndexOf 方法。该方法返回一个整数，表示待找字符串出
现在列表中的位置：  //var strList: TStringList;  strList := TStringList.Create;
  strList.Add('Beijing');
  strList.Add('Tianjing');
  strList.Add('Shanghai');
  strList.Add('Chongqing');
  str := 'Chongqing';
  case strList.IndexOf(str) of
    0:  ShowMessage('First');
    1:  ShowMessage('Second');
    2:  ShowMessage('Third');
    3:  ShowMessage('Forth');
    else ShowMessage('Other');
  end;
  strList.Free;  可以看到，这是比较麻烦的方法了，不过你可得记住这个方法，因为后面的讨论
将会讲到，这是最通用的方法。
  另：当然，把字符串转化为整型后用于 case 不只这一种方法。另一种是通过把
备选项全部转化为等长度后合并为一个字符串，然后用 Pos 函数返回某字符串的
位置。在此不再累述，请查阅《程序员》杂志（具体哪一期不记得了:-(）。法二：字符串转为字符型  这应该是最简单的一种方法，不过局限性比较大。如果你的备选项的第 N 个字
符（N 应为常数）都互不相同，那么你赚到了。这样，就可以通过取出这个字符，
来唯一标识你的字符串：  str := 'Chongqing';
  case str[1] of // 第一个字符都不同，所以取出第一个进行比较
    'B':  ShowMessage('First');
    'T':  ShowMessage('Second');
    'S':  ShowMessage('Third');
    'C':  ShowMessage('Forth');
    else  ShowMessage('Other');
  end;  不过如果你的备选项没有这样的特性，那么你就无缘使用这种方法了。法三：字符串转为枚举型  这种方法主要用到 RTTI 的特性。该方法的主要思路是，先把所有的备选项声名
为一个枚举类型的值，那么我们只要把要找的字符串也转换为枚举型，那么就可以
用 case 语句了。那么通过什么办法把一个字符串转化为枚举型呢？往下看：  // uses TypInfo; // 记得引用这个单元
  // type TMyStrSel = (Beijing, Tianjing, Shanghai, Chongqing);
  // 注意，上面这个定义不能放在某个函数内部哦，那样的话，它就没有运行类信息了
  // var strSel: TMyStrSel;  str := 'Chongqing';
  strSel := TMyStrSel(GetEnumvalue(TypeInfo(TMyStrSel), str));
  case strSel of
    Beijing:    ShowMessage('First');
    Tianjing:    ShowMessage('Second');
    Shanghai:    ShowMessage('Third');
    Chongqing:  ShowMessage('Forth');
    else        ShowMessage('Other');
  end;  稍做解释：GetEnumvalue 函数返回一个字符串对应的枚举型的值在某枚举类型
中的位置（要知道枚举类型是有顺序的，要不怎么叫顺序类型呢:-)），然后通过
一个强制类型转换将这个值转化为枚举型。于是就实现了把字符串转化为枚举型的
操作。  可以看到，在 case 语句这一段，我们的使用和理想中的使用方法几乎是一样的！
毕竟枚举类型可以做到见名知意嘛。的确比用前两种方法看起来直观得多。  当然，这并不是万能的方法，如果你的备选项有一个不符合 Delphi 的变量名命
名法则（如'AK-47'或中文等），则不能将其声明为一个枚举型，于是就不能使用这
个方法。如果是这样你就只能使用前两种方法了。极端的情况下，至少你还有第一
种方法可以使用 :-) 但在不少的场合，这种方法还是适用的。

Answer 6

有序类型。
如果个数是固定的，
可以case 枚举，

Answer 7

type
  TOrderList=(WinLevel, LocalZoom, Zoom, CT, ShowParam, HideParam,
       ImageMove, Reload, Smooth, Rotate90, Rotate180, Invert,
       FlipH, FlipV, Distance, Label_, PlayAVI, StopAVI);
var
CommandType: TOrderList;
begin
          case CommandType of
            WinLevel: ImageEnum[i].WinLevel(0, 0);
            LocalZoom: ImageEnum[i].LocalZoom;
            Zoom: ImageEnum[i].Zoom;
            CT: ImageEnum[i].CT;
            ShowParam: ImageEnum[i].ShowParam(1);
            HideParam: ImageEnum[i].ShowParam(0);
            ImageMove: ImageEnum[i].ImageMove();
            Reload: ImageEnum[i].Reload();
            Smooth: ImageEnum[i].Smooth(8);
            Rotate90: ImageEnum[i].Rotate(90);
            Rotate180: ImageEnum[i].Rotate(180);
            Invert: ImageEnum[i].Invert;
            FlipH: ImageEnum[i].Flip(0);
            FlipV: ImageEnum[i].Flip(1);
            Distance: ImageEnum[i].Distance;
            Label_: ImageEnum[i].Label_;
            PlayAVI: ImageEnum[i].PlayAVI(0);
            StopAVI: ImageEnum[i].StopAVI;
          end;
end;