L_xiaofeng——ini的资料

Question

给你找的，慢慢看好了
Delphi中Ini文件的读写
 金林樵 郭彩虹 
在Windows中的应用程序极大多数拥有自己的初始化文件，如PowerBuilder、Office及Cstar等。因此初始化文件的读写是每个高级程序员必须掌握的技术。虽然初始化文件的读写也可用Object Pascal中的文本文件一样读写，但因初始化文件不同于一般的文本文件，它有自己固定的格式（见下面的初始化文件是ucdos中提供的rdfnt.ini文件），如果用文本文件的方式读写，不仅格式转换十分繁琐，且很容易出现错误，为了方便程序员读写初始化文件中的数据，Delphi中向用户提供了一个TIniFile类，通过TiniFile类就可十分方便地读写初始化文件。Ucdos中rdfnt.ini文件的内容为：[True Type fonts directory]Dir=C:\WINDOWS\SYSTEM　[True Type fonts list]ARIAL.TTF=64ARIALBD.TTF=65ARIALI.TTF=66ARIALBI.TTF=67TIMES.TTF=68TIMESBD.TTF=69TIMESI.TTF=70TIMESBI.TTF=71COUR.TTF=72COURBD.TTF=73COURI.TTF=74COURBI.TTF=75[Use All True Type fonts]All=0

Answer 1

TiniFile类不是一个Delphi的部件，因此不能在Delphi的VCL模板中找到，它在Delphi 系统中的inifiles单元中定义，因此要使用TiniFile类，必须在使用该类的单元文件中用Uses inifiles指令明确地说明。TiniFile类中定义了许多成员函数，这里介绍几个使用频率较高的成员函数：  ⑴ Create（）  函数定义为： constructor Create(const FileName: string);该函数建立TiniFile类的对象。参数FileName是要读写的初始化文件名。若读写的文件在Windows的目录里（如system.ini文件），则可以直接写文件名而不必指定路径，否则就必须指定路径（如d:\ucdos\rdfnt.ini）。如按以下规则在规定的目录中存在该文件，则打开该初始化文件；否则在规定的目录里创建该初始化文件。  ⑵ ReadSections（）  过程定义为： procedure ReadSections(Strings: TStrings);该过程将从所建立的TiniFile类的对象（即与之关联的初始化文件）中读取所有的节点名（即用[]括号括起的那部分，如rdfnt.ini文件中的[True Type fonts list]）存入字符串列表中。参数Strings即为字符串列表的变量名。  ⑶ ReadSectionValues()  过程定义为： procedure ReadSectionValues(const Section: string; Strings: TStrings);  该过程将参数Section的值所对应的节点（如rdfnt.ini文件中的[True Type fonts list]）中的各个关键字（如ARIALBI.TTF）及其所含的值（如ARIALBI.TTF关键字值为67）读入参数Strings指明的字符串列表中。  ⑷ ReadSection()过程定义为： procedure ReadSection(const Section: string; Strings: TStrings);该过程将参数Section的值所对应的节点中的各个关键字读入参数Strings指明的字符串列表中。与ReadSectionValues()不同的是它没有读取各个关键字的对应值。  ⑸ ReadString()  函数定义为： function ReadString(const Section, Ident, Default: string): string;该函数返回以参数Section的值为节点名、参数Ident的值为关键字名所对应的关键字值（如[True Type fonts list]节中ARIALBI.TTF关键字的值为67）。当指定的节点或节内的关键字不存在时，则函数返回参数Default的缺省值。返回的值是一个字符串型数据。当指定节点中关键字值的数据类型不是字符串时，则可用ReadInteger()成员函数读取一个整型值，用ReadBool()成员函数读取一个布尔值。  ⑹ WriteString()过程定义为： procedure WriteString(const Section, Ident, Value: string);该过程将参数Section的值为节点名、参数Ident的值为关键字名的关键字值设置为参数Value的值。该过程设置的是字符串型数据。当指定节点和关键字均存在时，则用Value的值替代原值；如指定节点不存在，则在关联的初始化文件中自动增加一个节点，该节点的值为参数Section的值，并在该节点下自动增加一个关键字，关键字名为参数Ident的值，该关键字对应的值为参数Value的值；若节点存在，但关键字不存在，则在该节点下自动增加一个关键字，关键字名为参数Ident的值，该关键字对应的值为参数Value的值。若要设置整型值，可调用WriteInteger()成员函数；用WriteBool()成员函数设置布尔值。知道了以上函数的作用，要建立或读写一个初始化文件就不难了。下面以一个实际例子说明初始化文件的读取方法，步骤如下：

Answer 2

⒈ 在需要读写初始化文件的窗体（Form）上放置名为SectionComboBox、IdentComboBox的两个组合式列表框，其中SectionComboBox存放节点名，IdentComboBox存放所选择节点的关键字名。一个名为IdentValueEdit的输入框，存放对应关键字的值。名为CmdChang的修改命令钮可以用来修改关键字的值，修改后用名为CmdSave的存储命令钮将修改后的关键字的值存入关联的初始化文件。窗体对应的单元名设为IniUnit，窗体名设为IniForm，窗体布局如下图一所示： ⒉ 在IniUnit单元的interface部分用uses inifiles;说明要引用的TiniFile类所定义的单元名。并在变量说明部分定义TiniFile类的对象，如var IniFile: TiniFile;⒊ 建立窗体的OnCreate事件过程。使用TIniFile类的Create成员函数创建TIniFile对象，用该对象读写d:\ucdos目录中的rdfnt.ini初始化文件，并将该初始化文件中的所有节点通过ReadSections() 成员函数读入SectionComboBox组合式列表框中，用ReadSection()成员函数将第一个节点中的所有关键字读入IdentComboBox 组合式列表框，用ReadString()成员函数将第一个关键字的值送入IdentValueEdit输入框。⒋ 建立SectionComboBox组合式列表框的OnChange事件过程。当该选择列表框中的不同项目（即不同的节点名）时，用ReadSection()成员函数将选节点中的所有关键字读入IdentComboBox 组合式列表框，并用ReadString()成员函数将第一个关键字的值送入IdentValueEdit输入框。⒌ 建立IdentComboBox组合式列表框的OnChange事件过程。当该选择列表框中的不同项目（即不同的关键字名）时，用ReadString()成员函数将该关键字的值送入IdentValueEdit输入框。⒍ 建立命令钮CmdChang的OnClick事件过程。使IdentValueEdit输入框中的内容可以修改（不按该命令钮，IdentValueEdit输入框是不能修改的），并设置命令钮CmdSave有效，可以将修改后的关键字值存入关联的初始化文件中。⒎ 建立命令钮CmdSave的OnClick事件过程。如果关键字值已改变，则调用WriteString()成员函数将修改后的关键字的值存盘。⒏ 建立窗体的OnDestroy事件过程。当窗体失效时，将建立的TIniFile对象释放，以释放该对象所战用的系统资源。至此，运行该工程，初始化文件的读写已能顺利进行。当然还可以使用EraseSection()成员函数删除指定的节，也可用DeleteKey()成员函数删除指定的关键字，因篇幅有限，这里就不详细介绍了，有兴趣的可参考Delphi的使用帮助。下面是该单元的源程序代码：unit IniUnit; interface uses  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,  StdCtrls, inifiles; type  TIniForm = class(TForm)  SectionComboBox: TComboBox;  Label1: TLabel;  CmdSave: TButton;  CmdChang: TButton;  IdentComboBox: TComboBox;  IdentValueEdit: TEdit;  Label2: TLabel;  Label3: TLabel;  procedure FormCreate(Sender: TObject);  procedure SectionComboBoxChange(Sender: TObject);  procedure FormDestroy(Sender: TObject);  procedure CmdChangClick(Sender: TObject);  procedure CmdSaveClick(Sender: TObject);  procedure IdentComboBoxChange(Sender: TObject);  private  { Private declarations }  public  { Public declarations }  end; var  IniForm: TIniForm;{ Delphi中通过TIniFile类读写Windows的初始化文件 }  IniFile: TIniFile; implementation {$R *.DFM} procedure TIniForm.FormCreate(Sender: TObject);begin

Answer 3

{ 使用TIniFile类的Create成员函数建立TIniFile对象，该对象用来读写d:\ucdos目录中的rdfnt.ini文件，如果读写的文件在Windows的目录里（如system.ini），则可以直接写文件名而不必指定路径 }  IniFile:=TIniFile.Create('d:\ucdos\rdfnt.ini');{ 将TIniFile对象关联的初始化文件system.ini中的所有节（即用[]括号括起的那部分）的节名送入下拉式组合列表框SectionComboBox中 }  SectionComboBox.Clear;  IniFile.ReadSections(SectionComboBox.Items);{ 选择system.ini文件的第一个节名 }  SectionComboBox.ItemIndex:=0;  SectionComboBoxChange(Sender);  CmdSave.Enabled:=False;end; { 将组合列表框IniComboBox中所选择节中对应的各个变量及对应的值送入多行文本编辑器IniMemo中 }procedure TIniForm.SectionComboBoxChange(Sender: TObject);begin  IdentComboBox.Clear;  IniFile.ReadSection(SectionComboBox.Text,  IdentComboBox.Items);  IdentComboBox.ItemIndex:=0;  IdentComboBoxChange(Sender);end; procedure TIniForm.IdentComboBoxChange(Sender: TObject);begin  IdentValueEdit.Enabled:=False;  { 将选择的关键字值读入 }  IdentValueEdit.Text:=  IniFile.ReadString(SectionComboBox.Text,  IdentComboBox.Text,'');end; procedure TIniForm.CmdChangClick(Sender: TObject);begin  CmdSave.Enabled:=True;  IdentValueEdit.Enabled:=True;  IdentValueEdit.SetFocus;end; procedure TIniForm.CmdSaveClick(Sender: TObject);begin  if IdentValueEdit.Modified then begin  IniFile.WriteString(SectionComboBox.Text,  IdentComboBox.Text,  IdentValueEdit.Text);  end;  IdentValueEdit.Enabled:=False;  CmdSave.Enabled:=False;end; procedure TIniForm.FormDestroy(Sender: TObject);begin  IniFile.Free; { 释放创建的对象 }end; end.以上方法在Windows 95下用Delphi 3.0调试通过。

Answer 4

谢谢YANSEA，继续写啊，等待学习。

Answer 5

谢谢YANSEA，继续写啊，等待学习。

Answer 6

谢谢YANSEA，继续写啊，等待学习。

Answer 7

要利用.INI文件做程序有关数据的存储工作，就需要能读和写.INI文件，所以列了如下方法给大家参考：
从.INI文件中获取字符串
var
strResult:pchar;
begin
GetPrivateProfileString(
'windows', // []中标题的名字
'NullPort', // =号前的名字
'NIL', // 如果没有找到字符串时，返回的默认值
strResult, //存放取得字符
100, //取得字符的允许最大长度
'c:\forwin95\win.ini' // 调用的文件名
);
edit1.text:=strResult; //显示取得字符串
从.INI文件中获取整数
edit1.text:=inttostr(GetPrivateProfileInt(
'intl', // []中标题的名字
'iCountry', // =号前的名字
0,// 如果没有找到整数时，返回的默认值'c:\forwin95\win.ini' // 调用的文件名
));
向.INI文件写入字符串
WritePrivateProfileString(
'windows', // []中标题的名字
'load', // 要写入“=”号前的字符串
'accca', //要写入的数据
'c:\forwin95\win.ini' // 调用的文件名
);
向.INI文件写入整数
WritePrivateProfileSection(
'windows', // []中标题的名字
'read=100', // 要写入的数据
'c:\forwin95\win.ini' // 调用的文件名
);

Answer 8

对于INI文件的操作，我不多说了，仅仅就如何实现语言界面的切换做一个简单的说明：
首先，必须把所有的INI语言文件的结构统一，这样，我们只要传入INI的文件名，就可以通用了，例如我们可以做一个过程SetLanguage(const FileName:string);，这样只要用SetLanguage('CN.INI')就可以了，第二个需要注意的地方，你应该可以让用户选择语言界面的文件，因此程序启动的时候，应该搜索程序目录下面的所有INI文件，当然，你可以在INI文件里面添加一些附加的东西，例如，判断是否是语言INI文件还是其他的配置文件，显示的文字等等~~~~~，如果你的程序中还使用了类似ShowMessage('File Saved!')之类的语句，那么也应该用变量代替！！！例如：ShowMessage(MSG_FILE_SAVED);然后读取INI的时候，一起读入MSG_FILE_SAVED，这样才能保证所有的信息全部变成相应的语言！如果对于这些嵌入程序的信息你怕一个个很麻烦的话， 可以用数组来做~~~~~~~~~：）。接下来就是翻译文字了，这个就~~~~~~~~免了吧？最重要的一步到了：切换语言！我以前的方法是自己写一个过程，用Lable1.Caption:=Ini.ReadString(....)之类的，$^*$#@&^@*(^@(^$@^，现在想起来，怎么这么弱？：（，真的很笨，嗯咳~~~~~~不许笑，：），这个方法有一个缺点就是如果你添加一个控件就^$#@&*^%@&*了~~~~~~~~~，所以必须找一个更好的方法！看看下面的函数就知道了：
procedure SetLanguage(const FileName:string);
使用这个方法对于大多数的情况已经够了，但是有一个不方便的地方是如果动态创建窗体或者控件的话，就不行了~~~~~：（，不过你可以根据你的需要，可以修改上面的过程，然后在每一个窗体的OnCreate中添加代码就可以了，例如你把上面的过程改成对单个窗体的，就可以了：）。如果还有考虑不到的控件，你自己添加好了~~：），对于一些小程序来说，下面的已经够了：{****************************************
*      模块说明：利用切换INI切换语言函数*
*          作者：[email protected]        *
****************************************}
{****************************************
  下面的编译指定表示是否导出成一个INI文件
  一般的情况下面，没有必要修改，但需要母本
  INI的时候，可以把注释去掉
****************************************}
{$IFNDEF INI_EXPORT}
///{$DEFINE INI_EXPORT}
{$ENDIF}
{****************************************
  函数参数说明：
    FileName:Ini语言文件名
    msg:用于程序中的信息的保存数组
    IgnoreTagValue:需要忽略的组件的Tag值
  使用举例：
    var
      Msg:array of string;
    .....
    SetLanguage(ExtractFilePath(ParamStr(0))+'English.Ini',msg,$FF);
    那么函数会忽略所有Tag值为$FF的控件
****************************************}procedure SetLanguage(const FileName: string; var msg: array of string; const IgnoreTagValue: integer = $FFFF);
const
  ///下面是一些常量
  TRANS_SECTION     = 'Translations';
  MESSAGES          = 'Messages';
  COMMON            = 'Common';
  HINT              = 'Hint';
  CAPTION           = 'Caption';
  MSG_PRE           = 'SS_Msg_';
var
  i, j, k           : integer;
  Component         : TComponent;
  Control           : TControl;
  Strings           : TStrings;
  Id                : string;
  OldCaption        : pchar;
  L                 : integer;
begin
  with TIniFile.Create(FileName) do
  try
{$IFDEF INI_EXPORT}
    WriteString(COMMON, 'Application.Title', Application.Title);
    WriteBool(COMMON, 'CheckValid', True);
{$ELSE}
    if not ReadBool(COMMON, 'CheckValid', False) then exit; ///不是合法的语言文件
    Application.Title := ReadString(COMMON, 'Application.Title', Application.Title);
{$ENDIF}
    for i := Low(msg) to High(msg) do ///读取非控件的一些语言元素
{$IFDEF INI_EXPORT}
      WriteString(MESSAGES, MSG_PRE + IntToStr(i), msg[i]);
{$ELSE}
      msg[i] := ReadString(MESSAGES, MSG_PRE + IntToStr(i), msg[i]);
{$ENDIF}
    for i := 0 to Screen.FormCount - 1 do ///遍历程序所有窗体
    begin
{$IFDEF INI_EXPORT}
      WriteString(TRANS_SECTION, Screen.Forms[i].Name + '.' + CAPTION, Screen.Forms[i].Caption);
      WriteString(TRANS_SECTION, Screen.Forms[i].Name + '.' + HINT, Screen.Forms[i].Hint);
{$ELSE}
      Screen.Forms[i].Caption := ReadString(TRANS_SECTION, Screen.Forms[i].Name + '.' + CAPTION, Screen.Forms[i].Caption);
      Screen.Forms[i].Hint := ReadString(TRANS_SECTION, Screen.Forms[i].Name + '.' + HINT, Screen.Forms[i].Hint);
{$ENDIF}
      for j := 0 to Screen.Forms[i].ComponentCount - 1 do ///遍历窗体所有组件
      begin
        Component := Screen.Forms[i].Components[j] as TComponent;
        if Component.Tag = IgnoreTagValue then Continue; ///需要忽略的控件
        Id := Screen.Forms[i].Name + '.' + Component.Name + '.';
        if Component is TControl then ///普通的控件如：TButton,TSpeedButton,TBitBtn,TCheckBox....
        begin
          Control := Component as TControl;
/// 下面的代码是用来生成第一个INI文件使用的
{$IFDEF INI_EXPORT}
          WriteString(TRANS_SECTION, Id + HINT, Control.Hint);
{$ELSE}
          Control.Hint := ReadString(TRANS_SECTION, Id + HINT, Control.Hint);
{$ENDIF}
          if Control is TCustomEdit then Continue; ///忽略TMemo,TEdit之类的
          if (Component is TCustomListBox) or (Component is TCustomRadioGroup)
            or (Component is TCustomComboBox) then /// Listbox,RadioGroup,Combobox必须单独处理
          begin
            Strings := nil; ///本行用于忽略编译信息
            if Component is TCustomListBox then Strings := TCustomListBox(Component).Items;
            if Component is TCustomRadioGroup then Strings := TRadioGroup(Component).Items;
            if Component is TCustomComboBox then Strings := TCustomComboBox(Component).Items;
            for k := 0 to Strings.Count - 1 do ///遍历Items的每一项
{$IFDEF INI_EXPORT}
              WriteString(TRANS_SECTION, ID + 'Items.' + IntToStr(k), Strings.Strings[k]);
{$ELSE}
              Strings.Strings[k] := ReadString(TRANS_SECTION, ID + 'Items.' + IntToStr(k), Strings.Strings[k]);
{$ENDIF}
          end;
          if Component is TCustomComboBox then Continue; ///Combobox还有一点儿问题，:-(
          L := Control.GetTextLen + 1;
          GetMem(OldCaption, L);
          Control.GetTextBuf(OldCaption, L);
{$IFDEF INI_EXPORT}
          WriteString(TRANS_SECTION, Id + CAPTION, OldCaption);
{$ELSE}
          Control.SetTextBuf(pchar(ReadString(TRANS_SECTION, Id + CAPTION, OldCaption)));
{$ENDIF}
          FreeMem(OldCaption, L);
          continue;
        end;
        if Component is TMenuItem then /// 处理TMenuItem
        begin
{$IFDEF INI_EXPORT}
          WriteString(TRANS_SECTION, Id + HINT, TMenuItem(Component).Hint);
          WriteString(TRANS_SECTION, Id + CAPTION, TMenuItem(Component).Caption);
{$ELSE}
          TMenuItem(Component).Hint := ReadString(TRANS_SECTION, ID + HINT, TMenuItem(Component).Hint);
          TMenuItem(Component).Caption := ReadString(TRANS_SECTION, ID + CAPTION, TMenuItem(Component).Caption);
{$ENDIF}
          Continue;
        end;
        if Component is TCustomAction then /// 处理TAction
        begin
{$IFDEF INI_EXPORT}
          WriteString(TRANS_SECTION, Id + HINT, TCustomAction(Component).Hint);
          WriteString(TRANS_SECTION, Id + CAPTION, TCustomAction(Component).Caption);
{$ELSE}
          TCustomAction(Component).Hint := ReadString(TRANS_SECTION, ID + HINT, TCustomAction(Component).Hint);
          TCustomAction(Component).Caption := ReadString(TRANS_SECTION, CAPTION, TCustomAction(Component).Caption);
{$ENDIF}
          Continue;
        end;
        if Component is TOpenDialog then  ///处理TOpenDialog,TSaveDialog,....
        begin
{$IFDEF INI_EXPORT}
          WriteString(TRANS_SECTION, Id + 'Filter', TOpenDialog(Component).Filter);
          WriteString(TRANS_SECTION, Id + 'Title', TOpenDialog(Component).Title);
{$ELSE}
          TOpenDialog(Component).Filter := ReadString(TRANS_SECTION, ID + HINT, TOpenDialog(Component).Filter);
          TOpenDialog(Component).Title := ReadString(TRANS_SECTION, CAPTION, TOpenDialog(Component).Title);
{$ENDIF}
        end;
      end;
    end;
  finally
    Free;
  end;
end;